Copier coller ligne selon valeurs d'une colonne

Bonjour à toutes et tous,

Samedi je vous ais demandé de l'aide, ci-joint le message de samedi.

<<Je souhaiterai copier/coller automatiquement des lignes de mon tableau avec la mise en forme Feuil 1 à partir de la colonne C jusqu'à la colonne K en fonction de la valeur de la colonne J >49 , dans la Feuil 2 en colonne A jusqu'à I.

Je sais qu'une macro serai la solution, mais comme vous en avez l'habitude.... de le lire, je n'y connaît rien ou presque en VBA.

Pouvez-vous m'aider dans mon projet>>.

gmb m'a fait un code qui fonctionne parfaitement, je pensais m'en sortir et l'adapter a l'ensemble de mon fichier, a savoir pour plusieurs feuilles.

Hélas... J'ai présumé de mes forces intellectuelles, le VBA s'apprend avec beaucoup de temps et la jeunesse de mes neurones fou le camp.

Donc je souhaiterai adapter s'il est possible le code de gmb pour plusieurs feuilles, je vous joins le fichier modifié.

Pouvez-vous m'aider a adapter le code pour plusieurs feuilles.

Merci d'avance

Bonsoir mdo100, le forum

A tester :

Option Explicit
Sub copier()
Dim rng As Range, ws As Worksheet
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    On Error Resume Next
    With Sheets("Feuil6").Range("a1").CurrentRegion
        .Offset(1).Resize(.Rows.Count - 1).Clear
    End With
    On Error GoTo 0
    For Each ws In Worksheets
        With ws
            If .Name <> "Feuil6" Then
                .Activate
                With .Range("c7", Range("c" & Rows.Count).End(xlUp)).Resize(, 9)
                    .AutoFilter 8, ">49"
                    On Error Resume Next
                    Set rng = .Offset(1).Resize(.Rows.Count - 1).SpecialCells(12)
                    On Error GoTo 0
                    If Not rng Is Nothing Then
                        rng.Copy
                        Sheets("Feuil6").Range("a" & Rows.Count).End(xlUp)(2).PasteSpecial
                    Else
                        MsgBox "Aucune donnée en " & ws.Name
                    End If
                    .AutoFilter
                End With
                Set rng = Nothing
            End If
        End With
    Next
    Sheets("Feuil6").Activate
    Application.ScreenUpdating = True
    Application.EnableEvents = True
End Sub

klin89

Bonsoir Klin89, toutes et tous,

Merci de reprendre mon projet depuis samedi, votre macro fonctionne parfaitement, mais je suis obligé de mettre un bouton.

N'y a t-il pas un moyen pour quelle soit automatique.

Autrement dit, dés qu'une valeur dans mes feuilles en colonne "J" change >à 49 ou <à 49 la macro s'exécute immédiatement.

A +