Nombre de valeurs uniques dans des cellulles en couleur

Bonjour le forum,

Je souhaiterais solliciter votre aide pour une formule excel (ou macro, VBA) pour laquelle j'ai des difficultés.

Je dispose d'un tableau comme celui que je (joins en image) dans lequel j'ai des prénoms et des cellules en couleur qui contiennent elles aussi des prénoms.

Je recherche comment obtenir le nombre de valeurs uniques qui se trouvent dans les cellules en couleur (dans mon tableau par exemple la réponse est 3 puisque j'ai 4 cellules en couleur mais un doublon, donc 3 uniques et en couleur).

J'espère être claire.

Merci d'avance pour votre aide !!!

Bonjour,

Une petite fonction personnalisée à essayer :

Function NBVALUNIQUECOUL(plage As Range) As Long
    Dim d As Object, c As Range
    Set d = CreateObject("Scripting.Dictionary")
    For Each c In plage
        If c.Interior.ColorIndex <> xlColorIndexNone Then
            If c.Value <> "" Then d(c.Value) = ""
        End If
    Next c
    NBVALUNIQUECOUL = d.Count
End Function

Coller le code dans un module standard.

Utiliser comme une fonction d'Excel : elle réclame une plage de cellules en argument, et renvoie le nombre de valeurs uniques placées dans des cellules colorées (y compris blanc).

Cordialement.

Bonjour Excel_questions, bonjour le forum,

Peut-être comme ça :

Sub Macro1()
Dim PL As Range 'déclare la variable PL (PLage)
Dim CEL As Range 'déclare la variable CEL (CELlule)
Dim D As Object 'déclare la variable D (Dictionnaire)

Set PL = Range("C5:Q12") 'définit la palge PL (à adapter à ton cas)
Set D = CreateObject("Scripting.Dictionary") 'définit le dictionnaire D
For Each CEL In PL 'boucle sur toutes les cellules CEl de la plage PL
    'si la cellule est colorée, alimente le dictionaire D
    If CEL.Interior.ColorIndex <> xlNone Then D(CEL.Value) = ""
Next CEL 'prochaine cellule de la boucle
Range("F1").Value = UBound(D.keys) + 1 'renvoie dans F1 (à adapter à ton cas) le nombre de cellules colorées sans doublons
End Sub

[Édition]

Arf ! grillé par MFerrand que je salue au passage...

Merci beaucoup MFerrand et ThauThème ! Tout fonctionne parfaitement.

Merci pour votre aide et votre réactivité.

Excellente après-midi !

Ahh ! Salut ThauThème ! Réflexe dico dès qu'on parle valeurs uniques