Somme ou moyenne conditionnelles
Bonjour,
J'ai du mal avec Moyenne.si().
J'ai une colonne avec des ID, et une autre avec des valeurs.
J'aimerais faire la moyenne des valeurs dont la case ID correspondante commence par les deux caractères sélectionnés.
J'ai donc
Moyenne.si()
et Gauche()
A combiner. Mais je ne peux pas rentrer de plage dans gauche.
Comment faire ?
bonjour
une petite maquette de ce que tu as(+/-20lignes) ;est vivement recommandée
cordialement
Bonjour le forum,
D2 :
=SOMMEPROD((GAUCHE(A:A;2)=C2)*(B:B))E2:
=SOMMEPROD((GAUCHE(A:A;2)=C2)*(B:B))/SOMMEPROD(--(GAUCHE(A:A;2)=C2))
Bonjour,
Un essai avec les 2 caractères "EX" à chercher :
=MOYENNE.SI(PLAGE_TEST;"EX*";PLAGE_VALEURS)ou bien les 2 caractères à chercher dans une cellule disons F2 par exemple :
=MOYENNE.SI(PLAGE_TEST;F2&"*";VALEURS)Ou :
D2 :
=SOMME.SI(A:A;C2;B:B)E2 :
=MOYENNE.SI(A:A;C2;B:B)
Bonjour,
Merci pour vos réponses !
Vos solution marchent bien... pour peu que mon ID soit un string. Or c'est un float =/
J'ai un numéro de gamme, suivis d'un ID propre. Exemple :
8.1
8.1
8.2
8.2
8.5
8.8
9.2
9.2
9.28
9.8
9.9
9.6
Et j'aurais besoin de ne faire la moyenne QUE des 8,XXX par exemple.
Bonjour,
Voilà un exemple.
G5 :
=SIERREUR(SOMMEPROD((ENT($B$5:$B$22)=F5)*($C$5:$C$22))/SOMMEPROD(--(ENT($B$5:$B$22)=F5));"***")
Ou :
G5 :
=SIERREUR(SOMMEPROD(($B$5:$B$22>=F5)*($B$5:$B$22<F5+1)*$C$5:$C$22)/SOMMEPROD((B:B>=F5)*(B:B<F5+1));"")Ou :
G5 :
=SIERREUR(MOYENNE.SI.ENS(C:C;B:B;">="&F5;B:B;"<"&F5+1);"***")