Limiter la taille du tableau Excel

Bonjour,

J'ai beau cherché, je ne trouve pas de solution.

J'ai un fichier excel avec de nombreuses macros et feuilles.

Le problème est que alors que je n'utilise que les 1000 premières ligne, ma dernière ligne est la 1048524.

J'ai essayé de les masquer, de les supprimer,... Rien n'y fait, le fichier reste lourd et les macros tournent dans le vide.

J'ai essayé la macro karcher, elle arrive à me diminuer les cellules mais détruits pleins de choses dans les tableaux.

Quelqu'un connait-il une technique?

Merci d'avance!

Bonjour

• Tu sélectionnes la dernière ligne utile

• Tu cliques le bouton ‘’Rechercher et sélectionner’’ dans le bandeau

• Tu choisis ‘’Atteindre’’

• Tu cliques sur le bouton ‘’Cellules’’ dans la fenêtre qui s’est ouverte

• Tu choisis ‘’dernière cellule’’

• Tu maintiens la touche ‘’majuscule’’ enfoncée et tu cliques sur le bouton ‘’OK’’

• Tu supprimes les lignes de la zone sélectionnée : Boutons ‘’Supprimer’’ et Supprimer les lignes dans le bandeau

Tu refais la même manip pour les colonnes

Et tout cela, pour chaque feuille.

Il te faut encore faire un enregistrement de ton fichier pour qu’il soit enfin allégé ;

Et la dernière ligne utile ne devrait plus être la dernière de la feuille.

OK ?

Bye !

Bonjour lapulpachice, GMB, le forum,

tu peux essayer ceci, ça fonctionne bien chez moi (XL2007)

P.

Sub NettoieEtDerniereCellule()     ' Laurent Longre
Dim sht As Worksheet, DCell As Range, Calc As Long, Rien As String
On Error Resume Next
Calc = Application.Calculation
With Application
  .Calculation = xlCalculationManual
  .StatusBar = "Nettoyage en cours..."
  .EnableCancelKey = xlErrorHandler
  .ScreenUpdating = False
End With
For Each sht In Worksheets
  If sht.UsedRange.Address <> "$A$1" Or Not IsEmpty(sht.[a1]) Then
    Set DCell = sht.Cells.Find("*", , , , xlByRows, xlPrevious)(2)
    If Not DCell Is Nothing Then
      sht.Range(DCell, sht.Cells([A:A].Count, 1)).EntireRow.Clear
      Set DCell = Nothing
      Set DCell = sht.Cells.Find("*", , , , xlByColumns, xlPrevious)(, 2)
      If Not DCell Is Nothing Then _
         sht.Range(DCell, sht.[IV1]).EntireColumn.Clear
    End If
    Rien = sht.UsedRange.Address
  End If
Next sht
Application.StatusBar = False
Application.Calculation = Calc
End Sub

Bonjour,

La technique de gmb n'a pas fonctionné. J'ai suivi toutes les étapes mais ma dernière cellule restait la même.

Par contre la macro de patrick1957 a fonctionné au poil!

Merci!

Bonjour à tous

Désolé que ma méthode n'ait pas fonctionné.

Mais je confirme que la macro proposée par Patrick fonctionne super bien. Un vrai petit bijou que je me suis mis de coté.

Merci Patrick !

Avec un raccourci clavier, pas besoin de faire de manip.

Il suffit de d'ouvrir le fichier qui la contient, d'activer le fichier qu'on veut alléger et de lancer la macro avec le raccourci.

Qui dit mieux ?

Un grand crack ce Laurent Longre !

gmb a écrit :

Un grand crack ce Laurent Longre !

Oui dommage qu'il n'officie plus !

Il avait fait le concours de la formule de Pâques la + courte aussi

P.

Merci bcp Patrick 1957. Ta macro fonctionne du premier coup avec Office 365

Rechercher des sujets similaires à "limiter taille tableau"