NB.SI.ENS fonctionnement

Bonjour,

Je débute dans les formules Excel et je galère un peu sur cette formule.

J'ai une plage de nombre aléatoire de A à O sur 465 lignes. Je souhaiterais savoir quelle formule utiliser pour compter combien de fois sortent 2 numéros ensemble.

exemple: Le 5 et le 8 apparaissent 2 fois dans toute les lignes :

1/2/3/4/5/6/7/8/9/10/11/12/13/14/15

4/5/6/8/16/18/19/20/25/36/40/50/55/54/59

5/9/12/17/19/25/29/31/36/41/43/48/60/70/75

V2=1 W3=3

Si j’applique =NB.SI($A$1:$O$465;V2*W3) ça ne me donne pas le bon résultat

avec =NB.SI.ENS($A$1:$T$465;V3;A1:T465;W3) résultat 0

par contre =NB.SI($A$1:$O$465;V2) fonctionne mes a 1 chiffe

Auriez-vous une formule pour en comptabiliser 2 ensemble ?

Merci pour le temps que vous consacrerez à ma requête.

Bonjour et bienvenu sur le forum,

Un fichier, avec les données non confidentielles à traiter et résultat attendu, mis à disposition nous aiderait à proposer une solution.

Bonsoir,

Voici un fichier pour exemple

Merci

Bonne soirée

13exemple.xlsx (13.70 Ko)

Bonjour,

Par formule ça risque d'être coton.

Une proposition par macro.

eric

19exemple.xlsm (34.97 Ko)

merci

c'est ce que je recherchais par contre serait-il possible de conserver les 2 colonnes critères 1 et 2 en ayant le résultat à coté?

merci d'avance

Heuuu, ça complique, et 70x70/2 ça va te faire 2450 lignes...

Bonsoir ou bonjour,

Solution formule :

=SOMME(SI(FREQUENCE(($A$1:$O$64=V2)*LIGNE($A$1:$O$64)+($A$1:$O$64=W2)*LIGNE($A$1:$O$64);LIGNE($1:$64))>1;1))-1

La fonction FREQUENCE, comme SOMMEPROD, étant matricielle par définition, accepte une validation normale (Entrée) [lorsqu'on ne l'utilise pas pour renvoyer plusieurs résultats simultanément, en ayant préalablement sélectionné plusieurs cellule].

Dans ce genre d'évaluation, NB.SI manque de souplesse : en renvoyant une matrice, somme de 2 matrices correspondant à la matrice initiale mais où les valeurs correspondant aux critères sont remplacées par le numéro de ligne, chaque numéro de ligne doublé dans cette matrice résultante correspond à un cas recherché. FREQUENCE renvoie le nombre de valeurs par intervalles correspondant à chaque ligne (au cas particulier : 0 ou 1 ou 2). En comptant le nombre d'intervalles (lignes) ou la fréquence est supérieure à 1, on obtient notre résultat, à diminuer de 1 toutefois car FREQUENCE considère les intervalles extérieurs aux bornes et si on n'a pas de valeurs supérieures à 64, on a par contre toutes les valeurs hors critères qui auront renvoyé 0 et dont le nombre se trouve cumulé dans l'intervalle <1, lequel sera toujours très largement supérieur à 1 et qu'il faut donc déduire.

Cordialement

Ferrand

Bonsoir,

Merci beaucoup, c'est exactement la formule que je recherchais.

Bonne soirée.

Bonsoir,

J'ai voulu tester avec 3 critères,

J'aurai voulu savoir si j'ai bien appliquer la formule :

=SOMME(SI(FREQUENCE(($A$1:$O$64=U3)*LIGNE($A$1:$O$64)+($A$1:$O$64=V3)*LIGNE($A$1:$O$64)+($A$1:$O$64)+($A$1:$O$64=W3)*LIGNE($A$1:$O$64);LIGNE($1:$13))>1;1))-2

Merci et bonne soirée.

Bonjour,

=SOMME(SI(FREQUENCE(($A$1:$O$64=U3)*LIGNE($A$1:$O$64)+($A$1:$O$64=V3)*LIGNE($A$1:$O$64)+($A$1:$O$64=W3)*LIGNE($A$1:$O$64);LIGNE($1:$64))>2;1))-1

Bonjour,

merci pour la correction de la formule.

bonne soirée

Bonsoir,

auriez-vous une solution à me proposer ?

je souhaite intégrer la lettre correspondant à la colonne "I" dans la formule : =SOMME(SI(FREQUENCE(($A$1:$H$16=K2)*LIGNE($A$1:$H$16)+($A$1:$H$16=L2)*LIGNE($A$1:$H$16);LIGNE($1:$16))>1;1))-1

exemple : calculer le nombre de fois qu'il y a 1 et 2 et multiplier par le nombre correspondant à la casse "I" si il y a 1 et 2 dans cette ligne

a b i

1 2 3 3

1 4 5 0

1 2 1 1

1 2 =4

merci d'avance pour vos réponses

9exemple1.xlsx (9.52 Ko)

Bonsoir,

=SOMME(SI(FREQUENCE(($A$1:$H$16=K2)*LIGNE($A$1:$H$16)+($A$1:$H$16=L2)*LIGNE($A$1:$H$16);LIGNE($1:$16))>1;$I$1:$I$16))

J'ai eu un petit doute, mais remplacer le renvoi de 1 par la valeur de I fonctionne (en éliminant l'intervalle inférieur à 1, qui renvoie alors 0, d'où le -1 pour compenser saute).

Cordialement.

Bonsoir,

merci pour la formule.

bonne soirée

Bonsoir,

existe-t-il une formule pour multiplier le résultat N par le résultat J s'il y a bien L est M dans la formule?

merci

cordialement

10exemple5.xlsx (9.14 Ko)

Bonjour,

Je ne comprends pas ce que tu veux calculer...

On obtient 16 avec cette formule :

=SOMME(SI(FREQUENCE(($A$1:$H$16=L2)*LIGNE($A$1:$H$16)+($A$1:$H$16=M2)*LIGNE($A$1:$H$16);LIGNE($1:$16))>1;$J$1:$J$16))

Soit la même que précédemment, en ajustant les indications de colonnes modifiées.

Mais en excluant la colonne I parasite !

Si on inclut la colonne I dans le calcul, le résultat sera 21, car s'ajoutent les valeurs de J pour 3 lignes : la 10 (1 et 2), la 13 (2 et 2), la 15 (1 et 1).

Cordialement.

Rechercher des sujets similaires à "ens fonctionnement"