Comparer les valeurs de deux colonnes

Bonjour,

Je suis en débutante en VBA.

Je dois vérifier que quand dans la colonne H il y a écrit oui, dans la colonne L il y a bien écrit oui. Sinon, il faut que je colore la ligne.

Voici mon code actuel : 
Sub VérificationParitéBinômes()
Dim Plg As Range
Dim c As Range
Dim i As Long
Dim Msg As String

' définition de la plage de cellules
Set Plg = Application.InputBox("Sélectionnez la plage.", Type:=8)

' coeur de la macro
For Each c In Plg.Columns(1).Cells ' parcours
If c <> c.Offset(0, 1) Then ' test
Union(c, c.Offset(0, 0)).Interior.Color = vbYellow ' coloriage
i = i + 1 ' comptage
End If
Next

' préparation du message
If i = 0 Then
Msg = "Toutes les valeurs sont OK deux par deux."
Else
Msg = "Il y a des valeurs différentes sur " & i & " lignes !"
End If

' affichage
Z = MsgBox(Msg, vbInformation)

End Sub

J'espère que vous pourrez m'aider.

Cordialement,

Louise.

Bonjour,

Option Explicit
Option Compare Text
Sub VérificationParitéBinômes()
Dim Plg As Range
Dim c As Range
Dim i As Long
Dim Msg As String
    ' définition de la plage de cellules
    Set Plg = Range("H1:L" & Range("H" & Rows.Count).End(xlUp).Row)
    ' coeur de la macro
    For Each c In Plg.Columns(1).Cells ' parcours
        If c Like "oui" And c <> c.Offset(0, 4) Then ' test
            Range(c, c.Offset(0, 4)).Interior.Color = vbYellow ' coloriage
            i = i + 1 ' comptage
        End If
    Next
    ' préparation du message
    If i = 0 Then
        Msg = "Toutes les valeurs sont OK deux par deux."
    Else
        Msg = "Il y a des valeurs différentes sur " & i & " lignes !"
    End If
    ' affichage
    MsgBox Msg, vbInformation
End Sub

A+