copier coller valeurs

Y compris Power BI, Power Query et toute autre question en lien avec Excel
C
CHERIFRAM
Jeune membre
Jeune membre
Messages : 24
Inscrit le : 23 avril 2014
Version d'Excel : 2010

Message par CHERIFRAM » 23 février 2015, 12:52

Bonjour les ami(e)s,

j'aurais besoin de votre aide pour améliorer un code, voila dans mon code j'ai besoin de copier coller que les valeur se trouvant dans la range (cx5:db102) des onglet dont le nom commence par "ACT." et le copier dans l'onglet "Ecoutes". j'ai juste besoin de valeurs.

voici mon code actuel :
Sub ConsoEcoutes()
Dim og As Worksheet 'déclare la variable og (OnGlet)
Dim pe As Range 'décalre la variable pe (Plage à Effacer)
 
Application.ScreenUpdating = False 'masque les changements à l'écran
 
'*********************************
'suppression des anciennes données
'*********************************
If Sheets("Ecoutes").Range("c2").Value <> "" Then 'condition si la cellule c1 de l'onglet "Ecoutes" n'est pas vide
    Set pe = Sheets("Ecoutes").Range("c2").CurrentRegion 'définit la plage pe
    pe.Clear 'efface la plage pe
End If 'fin de la condition
 
'****************************************************
'récupération des données dans les différents onglets
'****************************************************
For Each og In Sheets 'boucle sur tous les onglets du classeur
    Select Case Left(og.Name, 4) 'action en fonction des 4 premières lettres du nom de l'onglet
        Case "ACT." 'cas "ACT."
            Set dest = Sheets("Ecoutes").Range("c65536").End(xlUp).Offset(1, 0) 'définit la cellue de destination
            Range(dest, dest.Offset(102, 0)).Value = og.Name 'place le nom de l'onglet dans la colonne c
            og.Range("cx5:db100").Copy dest.Offset(0, 1) 'copie et colle la plage à partir de la colonne B
    End Select 'fin de l'action en fonction de...
Next og 'prochain onglet de la boucle
Application.ScreenUpdating = True 'affiche les changements à l'écran
End Sub
Avatar du membre
ThauThème
Passionné d'Excel
Passionné d'Excel
Messages : 3'369
Appréciations reçues : 116
Inscrit le : 19 octobre 2014
Version d'Excel : 2010 FR

Message par ThauThème » 23 février 2015, 22:45

Bonsoir Cherifram, bonsoir le forum,,

C'est marrant que tu parles de ton code car les commentaires qui l'accompagnent me parlent beaucoup...
Si j'ai bien compris ta demande, le code modifié :
Sub ConsoEcoutes()
Dim PE As Range 'déclare la variable PE (Plage à Effacer)
Dim OG As Worksheet 'déclare la variable OG (OnGlet)
Dim DEST As Range 'déclare la variable DEST (cellule de DESTination)

Application.ScreenUpdating = False 'masque les changements à l'écran

'*********************************
'suppression des anciennes données
'*********************************
If Sheets("Ecoutes").Range("C2").Value <> "" Then 'condition si la cellule C2 de l'onglet "Ecoutes" n'est pas vide
   Set PE = Sheets("Ecoutes").Range("C2").CurrentRegion 'définit la plage PE
   PE.Clear 'efface la plage PE
End If 'fin de la condition

'****************************************************
'récupération des données dans les différents onglets
'****************************************************
For Each OG In Sheets 'boucle sur tous les onglets du classeur
   Select Case Left(OG.Name, 4) 'action en fonction des 4 premières lettres du nom de l'onglet
       Case "ACT." 'cas "ACT."
           Set DEST = Sheets("Ecoutes").Cells(Application.Rows.Count, 3).End(xlUp).Offset(1, 0) 'définit la cellue de destination DEST
           Range(DEST, DEST.Offset(102, 0)).Value = OG.Name 'place le nom de l'onglet dans la colonne C
           OG.Range("CX5:DB100").Copy ''copie la plage CX5:DB100
           DEST.Offset(0, 1).PasteSpecial (xlPasteValues) 'colle les valeurs de la plage à partir de la colonne D
   End Select 'fin de l'action en fonction de...
Next OG 'prochain onglet de la boucle
Application.CutCopyMode = False 'annule le clignotement lié au copier
Application.ScreenUpdating = True 'affiche les changements à l'écran
End Sub
À plus,

ThauTheme


Je suis Charlie
VBA m'éclate, les formules m'ennuient ! Je n'y peux rien c'est comme ça...
C
CHERIFRAM
Jeune membre
Jeune membre
Messages : 24
Inscrit le : 23 avril 2014
Version d'Excel : 2010

Message par CHERIFRAM » 23 février 2015, 23:30

merci thautheme

j'avais trouvé la solution en écrivant un code plus simple.
pour le code que j'ai partagé, je n'ai jamais dit que l'ai écrit, je l'avais pris du forum en faisant une recherche dans ce sujet.


merci en tout cas pour ton aide precieuse et l'aide de ce forum.
Avatar du membre
ThauThème
Passionné d'Excel
Passionné d'Excel
Messages : 3'369
Appréciations reçues : 116
Inscrit le : 19 octobre 2014
Version d'Excel : 2010 FR

Message par ThauThème » 24 février 2015, 00:18

Bonsoir Cherifram, bonsoir le forum,

Ça serait sympa pour ceux qui, comme toi, feraient un recherche et tomberaient sur ce fil, de leur proposer le code plus simple non ?...
À plus,

ThauTheme


Je suis Charlie
VBA m'éclate, les formules m'ennuient ! Je n'y peux rien c'est comme ça...
Répondre Sujet précédentSujet suivant
  • Sujets similaires
    Réponses
    Vues
    Dernier message