Remplacer plusieurs valeurs dans un fichier complet par une

Bonjour,

Je débute en excel et j'ai un projet de reporting avec différentes sources de données dont le nom de mes agents diffère.

Par exemple sur mon onglet 1 j'ai une extraction avec le nom de mes agents en colonne B sous la forme YY_MARTIN et sur l'onglet 2 ce même agent est référencé sous la forme martin_yy et sur le 3ème onglet il est référencé sous la forme XX_MARTIN. (toujours sur la colonne b)

Je souhaiterais trouver une solution qui me permette de remplacer sur mon onglet 2 et 3 la forme martin_yy et XX_MARTIN par la forme YY_MARTIN automatiquement, sachant que comme ce reporting est effectué sur l'année le nom de mes agents seront présents plusieurs fois sur les différents onglets.

Je vous remercie de l'aide que vous pourrez m'apporter.

Bonjour,

Une proposition sans fichier de makayel7

Bon réveillon.

Cdlt.

Option Explicit
Option Private Module
Public Sub Traitement()
Dim wb As Workbook
Dim ws As Worksheet, wsS As Worksheet
Dim rng As Range, rng1 As Range, c As Range
Dim x As String, y As String, z As String

    Application.ScreenUpdating = False

    Set wb = ActiveWorkbook
    Set wsS = wb.Worksheets("Onglet1")
    Set rng = wsS.Range("B2:B" & wsS.Range("B" & Rows.Count).End(xlUp).Row)

    For Each ws In wb.Worksheets
        If ws.Name <> wsS.Name Then
            For Each c In rng
                If Not c = vbNullString Then
                    x = c.Value
                    y = LCase(Split(c.Value, "_")(1) & "_" & Split(c.Value, "_")(0))
                    z = "XX_" & Split(c.Value, "_")(1)
                    Set rng1 = ws.Range("B2:B" & ws.Range("B" & Rows.Count).End(xlUp).Row)
                    With rng1
                        .Replace What:=y, Replacement:=x, Lookat:=xlWhole, MatchCase:=True
                        .Replace What:=z, Replacement:=x, Lookat:=xlWhole, MatchCase:=True
                    End With
                End If
            Next c
        End If
    Next ws

    Set rng = Nothing
    Set ws = Nothing
    Set wb = Nothing

End Sub

Merci beaucoup, j'ai réussi grâce à vous à faire ce qu'il fallait.