Fonction pour calcul de rémunération
Bonjour je suis en train de galérer pour calculer des rémunérations.
Je vous explique.
Le principe est simple, en fonction du chiffres réalisés les commerciaux sont rémunérés par paliers.
de 0 à 25 000 € = 1%
de 25 000 à 50 000 € = 2%
de 50 000 à 75 000 € = 3%
+ de 75 000 € = 4%
la commission se cumule mais pas le CA pour les commissions. En clair ce sont des paliers de 25 000 jusqu'à 75 000 € et le + est à 4 %
En gros je fais 90 000 € de CA je toucherai 250 € (de 0 à 25000 € à 1%) + 500 € (de 25000 à 50000 à 2%) + 750 € (de 50000 à 75 000 € à 3%) et 600 €(de 75 000 à 90 000 €à 4%) soit 2100 €
Le but dans excel est de pouvoir rentrer mon CA dans une case et en fonction de ce chiffres cela génère les montants par paliers et le montant cumulé.
Quelqu'un peut il m'aider ? ou me le faire pour que je gagne du temps... merci
Bonsoir le forum,
E3 :
=SOMME(($C$6:$C$10-$C$5:$C$9)*(CA-$B$5:$B$9+ABS(CA-$B$5:$B$9)))/2Formule matricielle à valider avec : CTRL MAJ ENTREE
mbbp
merci, mais je crois comprendre que vous êtes bcp plus doué que moi.
je comprends pas tout à votre réponse.
je n'arrive pas à la remettre en forme dans mon tableur!!!!
une idée?
Bnsoir,
Une autre proposition avec le détail des calculs et un fichier.
Cdlt.
Bonjour
Le CA en A1
=SOMMEPROD((A1>{0;25000;50000;75000})*(A1-{0;25000;50000;75000})*(0,01))Cordialement
merci à tous je suis sauvé:!!!!! si besoin l'apéro est dispo !!!
Re,
Et donc explications dans une autre vie.
mbbp
Aussi :
=SI(CA>75000;1500+(CA-75000)*0,04;SI(CA>50000;750+(CA-50000)*0,03;SI(CA>25000;250+(CA-25000)*0,02;CA*0,01)))mbbp
Bonjour
mbbp, on peut en rajouter
=CHOISIR(EQUIV(CA;{0;25000;50000;75000};1);CA*1%;250+(CA-25000)*2%;750+(CA-50000)*3%;1500+(CA-75000)*4%)Cordialement
bonjour
une solution tulipante
pas de matriciel; pas de tableau ; du direct
cordialement
Re,
Amadeus, encore une.
=SI(CA<B5;CA*C5;RECHERCHEV(B3;B5:E9;4;VRAI)+((B3-RECHERCHEV(B3;B5:E9;1;VRAI))*RECHERCHEV(B3;B5:E9;3;VRAI)))mbbp
Bonsoir
Tulipe: Un tout beau #REF!
mbbp: Avec des tableaux divers, on devrait pouvoir multiplier les solutions et les formules, mais quel intérêt quand on a directement le résultat sans tableau?
Cordialement
Amadéus a écrit :mbbp: Avec des tableaux divers, on devrait pouvoir multiplier les solutions et les formules, mais quel intérêt quand on a directement le résultat sans tableau?
Dans le cas présent, l'auteur du fil nous demande une formule pour un barème par tranches avec seulement 4 taux différents.
Les tableaux, comme celui présenté ci-dessous, permettent de travailler rapidement sur des barèmes avec de nombreuses tranches.
Il suffit de renseigner le barème (ici colonnes C & D) sans avoir à se préoccuper de la formule.
=SI(CA<$C$5;CA*D5;SI(CA<$C$5;0;INDEX(bareme;SI(CA<$C$5;0;EQUIV($G$4;$C$5:$C$15;1))))+SI(CA<$C$5;0;CA-INDEX(bareme1;SI(CA<$C$5;0;EQUIV($G$4;$C$5:$C$15;1))))*INDEX(taux;SI(CA<$C$5;0;EQUIV($G$4;$C$5:$C$15;1))+1))Et celui-là : c'est : "pour le plaisir".
mbbp
