Recherche une info et continue la macro

rebonjour le forum,

voila j'ai une macro qui lance un filtre et recherche une info en fonction de ce que l'utilisateur a saisi plus tot.

Je souhaiterai avoir une recherche qui se lance, juste apres la saisie par l'utilisateur et qui permettrait de savoir si la saisie rentrée existe dans ma colonne H.

Voici le code que j'ai fait, mais il se passe rien, ça passe dessus qu'il y ai ou pas l'info que j'ai saisi.

pouvez vous m'aider ?

'recherche si CCR number est dans le fichier

If Columns("H:H").Select Then

Selection.Find(What:=CCR, After:=ActiveCell, LookIn:=xlFormulas, _

LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _

MatchCase:=False, SearchFormat:=False).Activate

Else

MsgBox "Please, check the CCR Number and the Product Code"

Range("XFB2:XFC2").ClearContents

End If

dans le cas ou il trouve le numéro de CCR (info que j'ai saisi plus tot), je souhaite qu'il continue la macro, sinon qu'il me mette un message d'erreur, du style "Merci de vérifier votre numéro de CCR" avec le bouton ok pour revenir à l'userfum3 et le bouton annule qui ... attention roulement de tampour ... ...annulerait ma macro totale.

Merci par avance pour votre aide.

Laurent

Bonjour,

Une piste avec la procédure évènementielle "Change" de la feuille. La cellule cible est A1 donc quand tu entre ton CCR dans A1, la proc est appelée et la recherche faite en colonne H. Pour le test, à mettre dans le module de la feuille et à adapter à tes besoins :

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim CCR As String
    Dim Cel As Range

    'seulement sur la cellule A1
    If Target.Address(0, 0) <> "A1" Then Exit Sub

    'récupère le numéro entré en A1
    CCR = Target.Value

    'recherche si CCR number est dans le fichier
    Set Cel = Columns("H:H").Find(CCR, , xlValues, xlWhole)

    If Not Cel Is Nothing Then

        'ici le code si le numéro est trouvé...
        MsgBox "Trouvé en cellule '" & Cel.Address(0, 0) & "' !"

    Else

        MsgBox "Please, check the CCR Number and the Product Code"
        Range("XFB2:XFC2").ClearContents

    End If

End Sub

Hervé.