Reclasser des chiffres
Bonjour
encore besoin de vos lumieres juste 1 etape et c'est tout
Etape 1 reclasser du plus grand au plus petit
K14 a O14
et mettre les résultat en
K18 a O18
Exemple de K14 a 014 le plus grand c'est bien le chiffre 1 en N11 qui a 32,3 en N14
Donc en K18 le premier chiffre ecris sera 1
le second le 7 etc,,,
merci pour votre aide
si vous avez des questions allez y posez les moi
Bonjour,
en K18,
=INDEX($K11:$O11;EQUIV(GRANDE.VALEUR($K14:$O14;COLONNES($K:K));$K14:$O14;0))@ tirer vers la droite
Si il y aura des exæquos, fait un signe et je te donne une autre formule..
@ + +
merci beaucoup
tu peut me la donner au qu'a ou
milles merci pour votre aide
Bonjour
En K18, à incrémenter vers la droite
=INDEX($K$11:$O$11;EQUIV(GRANDE.VALEUR($K$14:$O$14;COLONNE()-10);$K$14:$O$14;0))cordialement
Bonjour @ tous,
Salut Amadeus,
en K18,
=INDEX($K11:$O11;EQUIV(GRANDE.VALEUR($K14:$O14-COLONNE($K:$O)/9^9;COLONNES($K:K));$K14:$O14-COLONNE($K:$O)/9^9;0))@ valider par Ctrl+Maj+Entree
@ tirer vers la droite
@ + +
Bonjour je prend laquelle des 2 formules?
celle la
=INDEX($K$11:$O$11;EQUIV(GRANDE.VALEUR($K$14:$O$14;COLONNE()-10);$K$14:$O$14;0))
ou celle la
=INDEX($K11:$O11;EQUIV(GRANDE.VALEUR($K14:$O14-COLONNE($K:$O)/9^9;COLONNES($K:K));$K14:$O14-COLONNE($K:$O)/9^9;0))
Bonjour,
La formule de l'ami Amdeus est comme ma première formule..
Pour ma 2eme formule c'est pour gérer les exæquos..
@ + +
re desoler ça ne marche pas ci joint le fichier pour voir l'erreur
Bonjour,
J'ai souligné en rouge qu'il faut valider par Ctrl+Maj+Entree
Voir PJ
@ + +
milles merci pour votre aide et votre patience
Bonjour,
fil terminé mais bon j'avais commencé un peu hier sur ta demande.
Dans ton premier fichier posté sur ce fil, solution via formule à placer en B16 dans la feuille Original
=INDEX($B$12:$I$13;1;EQUIV(GRANDE.VALEUR($B$13:$I$13;COLONNE(B$13)-1);$B$13:$I$13;))
Ensuite tirer la formule vers la droite
Amicalement