Ouvrir fichier dont le nom est dans une cellule

Bonjour, j'aimerai pouvoir ouvrir un fichier dont le nom est dans une cellule de mon fichier. J'arrive à récupérer le nom et le mettre dans une variable, mais je ne connais pas la syntaxe pour ensuite ouvrir correctement le fichier. et ça me serait très utile car j'ai plusieurs fichiers à ouvrir pour pouvoir compléter mon tableau.

Voici mon code :

Private Sub CommandButton1_Click()
Dim sh As Worksheet '(Onglet destination)
Dim CD As Workbook 'déclare la variable CD (Classeur Destination)
Dim CS As Workbook 'déclare la variable CS (Classeur Source)
Dim OS As Worksheet 'déclare la variable OS (Onglet source)
Dim Chemin_Dossier As String 'variable chemin_Dossier (Chemin d’Accès)
Dim Fichier_parcouru As String
Dim c, p, q, h, m, r As Range
Dim n, i As Long
Dim fichier As String

n = 1
i = 8

Set sh = ThisWorkbook.ActiveSheet

sh.Range("A8:D1000").ClearContents
sh.Range("G8:M1000").ClearContents
Chemin_Dossier = InputBox("Saisir le chemin du dossier dans lequel se trouve les fiches points i des bassins : ")

While n <= sh.Cells(2, "D")
    sh.Cells(i, "A") = "PT" & n
    sh.Cells(i, "G") = "BC" & n
    Fichier_parcouru = Chemin_Dossier & "\" & sh.Cells(i, "G").Value & ".xls"
    Workbooks.Open Filename:=Chemin_Dossier & "\" & sh.Cells(i, "G").Value & ".xls"
    Set CS = Workbooks(fichier)
    sh.Cells(i, "B") = CS.Sheets(1).Range("F40")
    sh.Cells(i, "C") = CS.Sheets(1).Range("F41")
    sh.Cells(i, "D") = CS.Sheets(1).Range("F42")
    n = n + 1
    i = i + 1
Wend
sh.Cells(i, "G") = "TOTAL"

End Sub

Je sais que c'est au niveau des lignes suivante que ça pose problème :

Set CS = Workbooks(fichier)

Avez vous des idées pour m'éclairer ?

Bonjour,

mets directement :

Set CS = Workbooks.Open(Chemin_Dossier & "\" & sh.Cells(i, "G").Value & ".xls")

au lieu de

    Workbooks.Open Filename:=Chemin_Dossier & "\" & sh.Cells(i, "G").Value & ".xls"
    Set CS = Workbooks(fichier)

Merci ça marche nickel !