Somme.si.ens ????

Bonjour.

Merci de jeter un coup d’œil sur mon classeur et de me corriger, la formule n'affiche aucune erreur et pourtant ne donne pas de résultat.

Merci à vous.

Bonjour,

C'est la date qui pose problème.

Vous cherchez dans la colonne date (col. F), la date "2019" (qui n'est pas une date valide, car au format date ça correspond au 11/07/1905).

Il faut donc remplacer :

;DEVIS!F:F;$A$1 et ;DEVIS!F:F;Reporting!$D$6

Par :

DEVIS!$F:$F;">="&C$6;DEVIS!$F:$F;"<"&MOIS.DECALER(C$6;1)

Les noms des mois sont à remplacer par des dates valides. La formule pour janvier :

=DATE($A$1;COLONNE()-2;1)

Le fichier corrigé :

PS : personnellement je virerais tout ça pour mettre un simple TCD...

Bonsoir

Merci à vous pedro22, je vais verifier votre solution et reviens vers vous.

J'ai essayer la façon TCD mais je suis obligé de travailler sur ce genre de canevas.

Merci encore.

Bonsoir!

La réponse de pedro22 est parfaite et merci infiniment pour son aide précieuse.

Je voudrais abuser de votre temps pour vous demander de me corriger la formule suivante qui fait abstraction de la catégorie en A2.

=Si(A2<> " Totalité";SOMME.SI.ENS(DEVIS!$L:$L;DEVIS!$F:$F;">="&C$5;DEVIS!$F:$F;"<"&MOIS.DECALER(C$5;1);DEVIS!$E:$E;$A$2;DEVIS!$M:$M;$A6);SOMME.SI.ENS(DEVIS!$L:$L;DEVIS!$F:$F;">="&C$5;DEVIS!$F:$F;"<"&MOIS.DECALER(C$5;1);DEVIS!$M:$M;$A6))

Merci à vous

Correct à première vue, mais il est peut-être possible de faire plus simple :

=SOMME.SI.ENS(DEVIS!$L:$L;DEVIS!$F:$F;">="&C$5;DEVIS!$F:$F;"<"&MOIS.DECALER(C$5;1);DEVIS!$E:$E;SI($A$2<>"Totalité";"*";"Totalité");DEVIS!$M:$M;$A6)

A tester.

Bonjour,

Ta formule revisitée puisque tu travailles avec un tableau structuré.

Cdlt.

Bonsoir Pedro22

La formule est bonne mais ne donne pas le résultat désiré, je voudrais que si l'option "Totalité" est choisie les montants sont toltalisés sans tenir compte des catégories, qua l'année en A1; le pois et le commercial qui sont des critères.

Exemple pour le prosect00 le montant en 2019 sera = 654 906 079.10.

Merci à vous.

Bonjour à vous Jean-Eric et Pedro22

En principe si je choisi totalité en A2

le montant total pour Prospect00 en 2018 = 1 607 894 126.85 et 2019 = 654 906 079.10.

Merci à vous de me corriger.

Re,

j'avais omis un <= !...

=@SI($A$2<> "Totalité";SOMME.SI.ENS(TDevis[Montant];TDevis[Date devis];">="&C$5;TDevis[Date devis];"<="&FIN.MOIS(C$5;0);TDevis[DES CATEG];$A$2;TDevis[Commercial];$A6);
SOMME.SI.ENS(TDevis[Montant];TDevis[Date devis];">="&C$5;TDevis[Date devis];"<="&FIN.MOIS(C$5;0);TDevis[Commercial];$A6))

Re-bonsoir Jean-Eric

=@SI($A$2<> "Totalité";SOMME.SI.ENS(TDevis[Montant];TDevis[Date devis];">="&C$5;TDevis[Date devis];"<="&FIN.MOIS(C$5;0);TDevis[DES CATEG];$A$2;TDevis[Commercial];$A6);

SOMME.SI.ENS(TDevis[Montant];TDevis[Date devis];">="&C$5;TDevis[Date devis];"<="&FIN.MOIS(C$5;0);TDevis[Commercial];$A6))

Ça marque une erreur sur la partie de la formule que j'ai mes en gras et souligné.

Merci à vous.

Re,

TDevis est le nom du tableau !...

Cdlt.

Merci infiniment Jean-Eric.

Ça marche très bien.

Je clôture le post

Rechercher des sujets similaires à "somme ens"