Copier une variable Excel vers document Word

Bonjour

Suis un peu embeté pour effectuer une manip qui consiste a reporter une variable de type string dans un document word

ma variable est "Q" il s'agit simplement d'une chaine de caractères .

j'ai utilisé les instructions suivantes :

Dim WordApp As Word.Application
Dim WordDoc As Word.Document
Set WordApp = CreateObject("Word.Application")
WordDoc.SaveAs "C:\users\rocket\desktop\" & "Extraction du " & Format(Date, "dd mmmm yyyy") & " au " & Format(Date+2, "dd mmmm yyyy") & " .doc"
ActiveDocument.Range.Text = Q   'c'est ici dans le document word crée que la variable "Q" doit être reportée  mais ça ne marche pas 

Apres avoir bien cherché , je ne trouve pas une facon de corriger ma ligne en defaut , Auriez vous une idée de la facon d'ecrire cela ?

Merci .

Bonjour,

Et si ta variable alimentait une cellule excel ; il te serait très facile ensuite de faire un "copié" et "coller avec liaison" de

cette cellule dans word.

Bonjour,

Pour que ça puisse fonctionner, il te faut ajouter un document :

Sub Test()

    Dim WordApp As New Word.Application
    Dim WordDoc As Word.Document
    Dim Fichier As String
    Dim Q As String

    Fichier = "C:\users\rocket\desktop\" & "Extraction du " & Format(Date, "dd mmmm yyyy") & " au " & Format(Date + 2, "dd mmmm yyyy") & " .doc"

    'texte devant être inscrit
    Q = "Le texte que je veux inscrire dans le nouveau document Word !"

    'rend l'application visible (pour en contrôler le texte entré) cette ligne peut être supprimée !
    WordApp.Visible = True

    'ajoute un document, sans ça, ça ne fonctionne pas !!!
    Set WordDoc = WordApp.Documents.Add

    'y inscrit le texte
    WordDoc.Range.Text = Q

    'enregistre
    WordDoc.SaveAs Fichier

    'ferme le document et quitte l'application, en commentaire ici pour pouvoir contrôler ce qui est entré !
'    WordDoc.Close
'    WordApp.Quit

End Sub

Un grand merci Theze !! c est tres détaillé merci d avoir pri le temps de répondre à ma question

Bonjour,

Content de t'avoir aidé