Enregistrer tableur en jpeg

Bonjour,

Ma question est simple, mais la réponse semble difficile à obtenir

J'ai créé un tableur d'analyse.

Comme je gère un groupe Facebook, il m'arrive de partager mes résultats avec les membres.

En temps normal, j'exporterais en PDF, mais quand on commente sous une publication, on ne peut que partager une photo (jpg donc).

Du coup, actuellement, j'utilise une méthode un peu barbare :

- je copie/colle mon tableau sous paint puis j'enregistre.

Résultat : une image pas très belle

J'ai essayé les impr écran, mais grosse perte de temps, car si je dézoom, on ne lit rien et je dois faire du patchwork.

Bref, à part un logiciel en ligne, existe t-il une méthode sous Excel 2016 pour exporter une sélection en image jpeg ?

Merci !

Bonjour,

Une possibilité consiste à passer par la création d'un graphe ...

A tester la macro suivante :

Sub ExporterPlage()
   ' Adapter le Répertoire et le Nom du fichier ....
   Const FName          As String = "C:\Temp\ExportPlage.jpg"
   Dim rng              As Range
   Dim shtTemp          As Worksheet
   Dim chtTemp          As Chart

   Application.ScreenUpdating = False
   ' Adapter Plage
   Set rng = Feui1.Range("A4:E18")

   Set shtTemp = Worksheets.Add
   Charts.Add
   ActiveChart.Location Where:=xlLocationAsObject, Name:=shtTemp.Name
   Set chtTemp = ActiveChart
   rng.CopyPicture Appearance:=xlScreen, Format:=xlPicture
   chtTemp.Paste
   chtTemp.Export Filename:=FName

   Application.DisplayAlerts = False
   shtTemp.Delete
   Application.DisplayAlerts = True
   Application.ScreenUpdating = True
End Sub

En espèrant que cela t'aide

Bonsoir,

Il me semble que cela ne fonctionne pas avec Excel 2016 et les versions plus récentes.

Voici ma suggestion:

Sub ExporterPlage2()

'https://forum.excel-pratique.com/viewtopic.php?f=2&t=126629&start=10

    Dim Plage  As Range
    Dim Chemin As String, MonImage As String

    Application.ScreenUpdating = False

    Set Plage = Range("A4:E18")                   'Ma plage de cellule à copier
    Chemin = "C:\Temp\"                           '<<== à adapter
    MonImage = "ExportPlage.jpg"                  '<<== à adapter

    Plage.CopyPicture

    With ActiveSheet.ChartObjects.Add(0, 0, Plage.Width, Plage.Height).Chart
        .Parent.Activate
        .Paste
        .Export Filename:=Chemin & MonImage, FilterName:="jpg"
        .Parent.Delete
    End With

    Application.ScreenUpdating = True

End Sub

Cordialement

Merci !

J'espérais qu'il existe une autre méthode que les macros, car je n'en ai encore jamais utilisés (mon apprentissage de Excel date d'il y a + 15 ans !)

Mais je vais chercher des tutos, pour voir comment ça fonctionne

Bonjour,

Et en 15 ans t'as pas été foutu de te lancer dans le VBA...

Utiliser une macro gentiment pondue par un internaute n'est pourtant pas sorcier !

Remarque t'es un peu comme moi : Ça fait au moins 15 ans qu'il y a un téléphone portable à la maison et je sais toujours pas m'en servir pour autre chose que lire un sms...

En tout cas les 2 macros fonctionnent correctement sous 2016.

A+

Maiwenn a écrit :

Merci !

J'espérais qu'il existe une autre méthode que les macros, car je n'en ai encore jamais utilisés (mon apprentissage de Excel date d'il y a + 15 ans !)

Mais je vais chercher des tutos, pour voir comment ça fonctionne

Bonjour,

Si dans ton Excel tu as déjà activé les macros ... il te suffit de :

1. Faire Alt F11 pour ouvrir la fenêtre

2. Depuis le menu Insérer un module

3. Faire un clic sur le module pour l'ouvrir à droite

4. Et y copier la macro

5. Faire Alt F11 pour fermer la fenêtre

6. Faire Alt F8 pour lancer la macro

Voilou ...