Liens hypertextes et onglets
Bonjour à tous,
Je suis bloqué sur un petit problème de liens hypertextes.
J'ai repris le code ci-dessous que j'ai adapté.
Le but étant de créer un onglet sur base d'un modèle ceci en double-cliquant sur une cellule de la feuille récapitulative "Tableau_2019"
Le nom de l'onglet résultant porte le même nom que la cellule. Tout fonctionne bien.
Maintenant je désire en même temps que la création de l'onglet, qu'un lien hypertexte soit directement créé sur la cellule, ce qui me permettrai d'accéder directement à l'onglet en question.
Est-ce que quelqu'un a une solution?
Merci.
Fredyne
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Not Intersect(Target, Range("E4:E" & Range("E" & Rows.Count).End(xlUp).Row)) Is Nothing Then
On Error GoTo Fin
Sheets(Target.Value).Select
Exit Sub
Fin:
Cancel = False
a = MsgBox("Pas de feuille existante. Voulez-vous la creer ?", vbYesNo + vbQuestion + vbDefaultButton2)
If a = vbYes Then
Sheets("Modele").Copy after:=Sheets(Sheets.Count)
ActiveSheet.Name = Target
End If
End If
Cancel = True
End Sub
Bonjour,
A tester.
Cdlt.
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim ws As Worksheet, Response As VbMsgBoxResult
If Not Intersect(Target, Range("E4:E" & Range("E" & Rows.Count).End(xlUp).Row)) Is Nothing Then
Cancel = True
On Error Resume Next
Set ws = Worksheets(Target.Value)
On Error GoTo 0
If ws Is Nothing Then
Response = MsgBox("Pas de feuille existante. Voulez-vous la creer ?", vbYesNo + vbQuestion)
If Response = vbYes Then
Sheets("Modele").Copy after:=Worksheets(Worksheets.Count)
Set ws = ActiveSheet
ws.Name = Target
Me.Hyperlinks.Add _
Anchor:=Target, _
Address:="", _
SubAddress:=ws.Name & "!A1", _
TextToDisplay:=ws.Name
End If
Else
ws.Activate
End If
End If
End Sub
Bonjour Jean-Eric,
La classe un grand MERCI, tout fonctionne à merveille.
Ce code est parfait.
Cordialement.
Fredyne