Fermer un classeur après récupération de données

Bonjour à tous,

j'ai un code VBA, qui me permet de récupérer les données d'une feuille dans un classeur, et de me transferer ces données vers une feuille de mon classeur actif.

Jusque là pas de problème.

Seulement, je souhaiterais qu'après ce transfert, la feuille qui m'a permis de récupérer ces données, ce ferme sans enregistrement.

Voici le code en question :

Sub RecuperationDesDonnees()

Dim ClasseurActif As String

Dim FichierAOuvrir As String

'Note le nom du classeur actif

ClasseurActif = ActiveWorkbook.Name

'Ouvre le fichier cible

FichierAOuvrir = Application.GetOpenFilename()

Workbooks.Open Filename:=FichierAOuvrir

'Copie les données de l'onglet désiré

Sheets("Sauv").Select

Cells.Select

Selection.Copy

'Colle les données dans le classeur actif

Windows(ClasseurActif).Activate

Sheets("Sauv").Cells(1, 1).Select

ActiveSheet.Paste

End Sub

merci encore de votre aide

titi32600

Bonsoir,

une proposition

Sub RecuperationDesDonnees()

    Dim wssauv As Object, wb As Object
    Dim FichierAOuvrir As String

    'mémorise le nom de l'onglet dans lequel recevoir la copie
    Set wssauv = ThisWorkbook.Sheets("sauv")

    'Ouvre le fichier cible
    FichierAOuvrir = Application.GetOpenFilename()

    Set wb = Workbooks.Open(FichierAOuvrir)

    'Copie les données de l'onglet désiré
    wb.Sheets("sauv").UsedRange.Copy wssauv.Cells(1, 1)
    wb.Close False

End Sub

Salut h3so4

Impeccable

Cela me convient tout à fait

Merci encore

Titi32600