Nombre de date qui tombent cette semaine
Bonjour,
J'aimerai faire une formule qui calcul combien de "cellules dates" tombent cette semaine (du samedi au vendredi) (la semaine ou je consulte mon tableau).
Par exemple je consulte mon tableau le lundi et je connais le nombre d'actions que j'aurai à réaliser dans la semaine (depuis samedi dernier jusqu'à vendredi).
Autrement dit :
au momment ou je consulte je veux connâitre le nombre de dates qui tombent cette semaine du samedi au vendredi.
fichier d'exemple en PJ
Merci d'avance pour votre aide,
Bonjour,
Voici une proposition pour le premier cas :
=NB.SI.ENS(A:C;">="&AUJOURDHUI()-JOURSEM(AUJOURDHUI();3);A:C;"<="&AUJOURDHUI()-JOURSEM(AUJOURDHUI();3)+5)
Pour le second ("entre samedi et vendredi"), je n'ai pas bien compris à quoi celà correspond ? Entre vendredi et samedi (inclus) de la semaine en cours (soit 2 jours), ou entre le samedi précédent et le vendredi de cette semaine ?
Dans tous les cas, il s'agit d'une simple adaptation de la première formule...
Salut PEDRO,
Merci pour ta réponse:
par entre samedi et vendredi j'entends sdlmmjv de la semaine en cours.
Peut tu me donner un peu plus d'explication sur ta formule merci,
Salut PEDRO,
Merci pour ta réponse:
par entre samedi et vendredi j'entends sdlmmjv de la semaine en cours.
Peut tu me donner un peu plus d'explication sur ta formule merci,
Bonjour !
Mes semaines vont du lundi au dimanche, mais on peut faire ça sans trop de soucis...
Si on décompose la formule :
NB.SI.ENS : décompte le nombre de cellules qui respectent un ensemble de conditions. Ici on veut les dates >= au lundi ET <= au vendredi
AUJOURDHUI : donne la date du jour
JOURSEM : renvoie pour une date une valeur numérique correspondant à un jour de la semaine. Le paramètre 3 en fin de formule indique que la valeur 0 est renvoyée pour un lundi, 1 pour mardi, 2 mercredi, etc...
Si l'on soustrait cette valeur à la date du jour, on retombe sur la date du lundi de la semaine en cours. Si l'on ajoute 5, on tombe sur le vendredi. Exemple : nous sommes mercredi, JOURSEM(AUJOURDHUI();3) renvoie donc 2. Si l'on retire ces 2 jours au 05/12, on tombe sur le 03/12 (qui est bien un lundi).
Redis moi si ça n'est pas clair. Je te laisse proposer la formule pour le second cas, à partir de la première formule.
Bonjour,
Une tentative matinale (sam-ven) à tester et à optimiser !?
=NB.SI.ENS(A:C;">="&SERIE.JOUR.OUVRE.INTL(AUJOURDHUI();-CHOISIR(JOURSEM(AUJOURDHUI();16);0;1;2;3;4;5;6;7);"0000000");
A:C;"<="&SERIE.JOUR.OUVRE.INTL(AUJOURDHUI();+CHOISIR(JOURSEM(AUJOURDHUI();16);6;5;4;3;2;1;0);"0000000"))Bonjour, Salut à tous !
Pour simplifier :
-lundi-vendredi :
=NB.SI.ENS(A1:C38;">="&AUJOURDHUI()-MOD(AUJOURDHUI()+5;7);A1:C38;"<="&AUJOURDHUI()-MOD(AUJOURDHUI()+5;7)+4)-samedi-vendredi :
=NB.SI.ENS(A1:C38;">="&AUJOURDHUI()-MOD(AUJOURDHUI();7);A1:C38;"<="&AUJOURDHUI()-MOD(AUJOURDHUI();7)+6)Cordialement.
Bonjour,
Je reviens vers vous voici ma proposition de formule pour la solution de @pedro22
Je ne comprend pas trop le +5 en en fin de formule.
=NB.SI.ENS(A:C;">="&AUJOURDHUI()-JOURSEM(AUJOURDHUI();16);A:C;"<="&AUJOURDHUI()-JOURSEM(AUJOURDHUI();16)+5)
Merci d'avance pour votre éclairage sur le +5
Bonne journée à tous,
Bonjour,
+5 c'est pour ajouter 5 jours...
La première partie de la formule permet de déterminer la date du lundi, donc quand on ajoute 5 on tombe sur la date du vendredi.
bonjour
une contribution par matricielle
pour le premier cas
=SOMME(SI(SIERREUR(ENT(MOD(ENT((A1:C38-2)/7)+0,6;52+5/28))+1;"")=NO.SEMAINE(AUJOURDHUI());--(JOURSEM(A1:C38;2)<6);""))pour le second ,je crains qu'il faille remonter à la semaine anterieure
cordialement
Bonjour à tous
Merci infiniment pour vos réponses,
@pedro22
Dans ma proposition de formule le 16 signifie que je ma semaine commence le samedi et se termine le vendredi.
pour qu'Excel me retourne le nombre de dates tombant dans la semaine en cours (semaine qui commence le samedi et se termine le vendredi suivant) ne devrais je pas faire +6 en fin de formule ?
=NB.SI.ENS(A:C;">="&AUJOURDHUI()-JOURSEM(AUJOURDHUI();16);A:C;"<="&AUJOURDHUI()-JOURSEM(AUJOURDHUI();16)+6)
Que pensez vous de cette proposition de solution ?
J'aimerai égalment comprendre l'emplois du & devant la fonction AUJOURDHUI()
Merci,
Bonjour Marion,
Il te suffit d'isoler les formules concernées dans des cellules à part de vérifier la valeur qu'elles prennent à partir d'un cas concret... Tu auras ta réponse !
JOURSEM(AUJOURDHUI();16) = 6
AUJOURDHUI()-JOURSEM(AUJOURDHUI();16) = 04/01/2019
AUJOURDHUI()-JOURSEM(AUJOURDHUI();16)+6 = 10/01/2019
Cette manip' te permet de voir que la formule ne te donne pas les jours souhaités, et donc que la valeur +6 n'est pas la bonne...
Le "&" sert à accoler l'opérateur de comparaison souhaité, par exemple ">=". Ce qui permet à Excel d'interpréter : >=04/01/2019 pour la première partie de la formule.
Bonjour Pedro22,
Merci, en effet cela me parait beaucoup plus clair en posant les formules isolement.
Je crois avoir compris et que la bonne formule est donc :
=NB.SI.ENS(A:C;">"&AUJOURDHUI()-JOURSEM(AUJOURDHUI();16);A:C;"<"&AUJOURDHUI()-JOURSEM(AUJOURDHUI();16)+8)
Est-ce correct professeur ?
Merci pour votre aide,
Bonjour Marion,
Ta nouvelle formule me semble plus adaptée... Si on se base sur l'exemple d'aujourd'hui, tu comptes le nombre de lignes dont la date est supérieure au 11/01/2019 (vendredi dernier) et inférieure au 19/01/2019 (samedi prochain).
Aussi, je n'ai plus tes données en tête, mais si ton fichier indique des heures, par exemple 11/01/2019 08:45:00, il sera également comptabilisé, car Excel la compare au 11/09/2019 00:00:00.
Une formule plus précise serait plutôt :
=NB.SI.ENS(A:C;">="&AUJOURDHUI()-JOURSEM(AUJOURDHUI();16)+1;A:C;"<"&AUJOURDHUI()-JOURSEM(AUJOURDHUI();16)+8)
Bonjour,
Mon fichier ne contiens aucune donnée horaire.
Donc je considère que ma question est résolue par la formule suivante :
=NB.SI.ENS(A:C;">"&AUJOURDHUI()-JOURSEM(AUJOURDHUI();16);A:C;"<"&AUJOURDHUI()-JOURSEM(AUJOURDHUI();16)+8)
Merci à tous pour votre précieuse aide.
Je n'ai pas eut le temps de regarder les autres formules proposées mais j'espère que les autres propositions serviront un jour à quelqu'un d'autre.
merci à tous,