Formule date: Fête du travail, Action de Grâce

Bonjour,

je cherche une formule qui donne le premier lundi de septembre de chaque année, et une autre formule qui donne le deuxième lundi d'octobre de chaque année.

J'ai trouvé celle-ci pour Pâques

=ARRONDI(DATE(An_ref;4;MOD(234-11*MOD(An_ref;19);30))/7;)*7-6

, mais ça ne convient pas pour un jour fixe dans l'année.

Merci d'avance et bon week-end

Bonsoir,

pour le premier lundi de septembre d'une année inscrite en A1 :

=DATE(A1;9;7)-MOD(DATE(A1;9;7)-2;7)

et pour le deuxième d'octobre même principe avec +7 pour la deuxième semaine :

=DATE(A1;10;7)-MOD(DATE(A1;10;7)-2;7)+7

@ bientôt

LouReeD

Bonjour,

mettre l'années en cellule A1,

1er lundi de septembre de chaque année

=DATE(A1;9;1)+6-MOD(DATE(A1;9;1)+4;7)

2èm lundi d'octobre de chaque année.

=DATE(A2;10;1)+13-MOD(DATE(A2;10;1)+4;7)

Bonjour LouReed et Sabv,

Vos formules diffèrent quelque peu, et donnent le même résultat.

Si jamais, vous avez quelques minutes pour me les expliquer, ce serait grandement apprécié.

Merci encore pour votre aide précieuse.

A+

Bonsoir,

en y regardant de plus près ce sont le même mais elles ne "partent" pas de la même référence

Pour la mienne : =DATE(A1;9;7)-MOD(DATE(A1;9;7)-2;7)

Il faut déjà savoir qu'une date sous Excel est un chiffre entier dont le 1 correspond au 01/01/1900 et que le 01/09/2018 est le 43 344ième jour depuis le 01/01/1900.

Mon idée (et pas que la mienne) c'est de prendre la date du 7 septembre car au bout de 7 jours, fatalement il y a le premier lundi de ce mois,

donc le 07/09/2018 (si en A1 il y a 2018) a pour entier : 43350.

Maintenant le lundi est le deuxième jour de la semaine, donc -2

MOD renvoie le reste d'une division d'un nombre par un autre, donc MOD(43350-2;7) équivaut à dire :

le reste de (43350-2)/7 = 4 car 43350 / 7 = 6192 et reste 6 mais comme l'on fait -2 = 4

et si l'on fait le 7 septembre - 4 jours = 3, le 03/09/2018 est le premier lundi de septembre, pour le deuxième il suffit d'ajouter 7 car le deuxième lundi est placé 7 jours après le premier

Pour le premier dimanche il faut faire -1 et pour le premier samedi il faut faire -7...

Pour que l'année soit "automatique" il suffit de la mettre en variable avec A1 par exemple.

Si vous regardez les formules de sabV, il prend le premier jour du mois auquel il ajoute 6 donc il prend le 7ième jour du mois afin d'être sur d'avoir au moins un lundi dans le calcul, et comme il part du premier jour du mois il ajoute 4, plutôt que de retirer 2, mais pour moi "-2" est plus simple à retenir car lundi sous Excel par défaut est le deuxième jour de la semaine : =JOURSEM(DATE(A1;9;7)-MOD(DATE(A1;9;7)-2;7) = 2 si l'on ne met pas de paramètre à la fonction d'Excel.

@ bientôt

LouReeD

Bonsoir LouReed,

merci pour cette instructive leçon. J'apprécie.

Rechercher des sujets similaires à "formule date fete travail action"