Gestion plusieurs plages de cellules et N/A avec SOMMEPROD
Bonjour à tous,
Je vais essayer d'être le plus clair possible. J'ai plusieurs plages de cellules dans différents onglets. Je souhaiterais faire la somme des plages Feuil1!$A$1:$A$2 + Feuil2!$A$1:$A$2 + Feuil3!$A$1:$A$2. le problème c'est que dans les cellules, il y a des formules qui renvoie #N/A en cas d'erreur.
Feuil1 Feuil2 Feuil3
A A A
1 62,4215 #N/A 62,4215
2 #N/A 29,2 #N/A
J'ai essayé de me renseigner sur les forums et les formules matricielles, en vain...
Je vous remercie par avance pour votre aide.
Bonjour
Tu peux essayer
=SOMMEPROD(SOMME.SI(INDIRECT("Feuil"&LIGNE(INDIRECT("1:3"))&"!A1:A2");">"&0;INDIRECT("Feuil"&LIGNE(INDIRECT("1:3"))&"!A1:A2")))Cordialement
Bonjour aux deux,
Il faut traité le mal a la racine !
Le probléme vient des #n/a
supprime les #n/a en modifiant les formules qui te produisent des #n/a
ex
=recherchev(a1;a7:f9;2;0) ne trouve pas et indique #n/a
=sierreur(recherchev(a1;a7:f9;2;0);0), te renvoies 0 en cas d'erreur et ne vient pas polluer ta somme
Crdlmt
Bonjour thomas40140, salutatous,
tous d'abord merci à Amadéus pour avoir fait tous le travail,
ps/ si il y a un ligne de titre, c'est à dire que les données à calculer débute en ligne 2
formule matriciel à valider avec les touches ctrl+maj+enter
=SOMMEPROD(SOMME.SI(INDIRECT("Feuil"&LIGNE(INDIRECT("1:3"))&"!A1:A3");">"&0;INDIRECT("Feuil"&LIGNE(INDIRECT("1:3"))&"!A1:A3")))Bonjour à tous,
Merci pour vos réponses @sabV et @Amadéus. Cette solution marche par contre mes onglets s'appellent 907;917;918 . Il faut maintenant que j'essaye d'adapter cette formule.
@DjiDji59430: J'ai besoin d'afficher N/A dans ces formules en cas d'erreur car j'ai d'autres formules qui sont conditionnées en cas de N/A.
Bonne journée.
Cdlt.
Bonjour
Cette solution marche par contre mes onglets s'appellent 907;917;918 . Il faut maintenant que j'essaye d'adapter cette formule.
La formule initiale
=SOMMEPROD(SOMME.SI(INDIRECT("Feuil"&LIGNE(INDIRECT("1:3"))&"!A1:A2");">"&0;INDIRECT("Feuil"&LIGNE(INDIRECT("1:3"))&"!A1:A2")))ne fonctionne que si les feuilles sont Feuil1, Feuil2, Feuil3 c'est à dire si le nom "Feuil" est générique.
Avec des noms d'onglets divers et variés, il faut établir la liste des onglets concernés, donc, selon ta demande 907, 917 et 918 et nommer cette liste. (sur ce fichier, la liste est nommée "Liste_Feuilles")
De plus, comme tu indiques avoir une ligne de titres, la formule somme à partir de A2
=SOMMEPROD(SOMME.SI(INDIRECT(Liste_Feuilles&"!A2:A4");">"&0;INDIRECT(Liste_Feuilles&"!A2:A4")))Cordialement
Merci @ Amadeus !! Je sais que je vais être un peu embêtant mais Est-ce que tu crois que c'est possible d'utiliser cette formule mais avec plusieurs plages ?
Par exemple, faire la somme des plages A1:A3 , A10:19 etc...
Encore merci pour ta réactivité et tes solutions !!
Bonjour
Je pense qu'il te faut répéter la formule pour les différentes plages
=SOMMEPROD(SOMME.SI(INDIRECT(Liste_Feuilles&"!A2:A4");">"&0;INDIRECT(Liste_Feuilles&"!A2:A4")))+SOMMEPROD(SOMME.SI(INDIRECT(Liste_Feuilles&"!A10:A19");">"&0;INDIRECT(Liste_Feuilles&"!A10:A19")))Cordialement
Merci Amadéus, tout fonctionne correctement !
Bonne journée!