Envoyer par mail tous les fichiers que contient un répertoire

Bonjour à tous,

Me revoilà avec encore une question à propos de Mozilla Thunderbird. Je me rends compte que cette messagerie est difficile à piloter en VBA... mais bon pas le choix !

J'aimerai pourvoir joindre à mon message, tous les fichiers (5 ou 6) contenus dans un dossier spécifique. J'ai tenté avec ce code mais ça ne fonctionne pas :

Sub Envoyer_mail()

Dim destinataire, sujet, cc, chemin, monFichier, PJ As String

destinataire = Range("C6")
sujet = Range("C10")
cc = Range("c8")
body = Range("b13")

chemin = "C:\Users\user5\Desktop\Fichier\Envoi"
monFichier = Dir(chemin, vbNormal)

Do While monFichier <> ""
monFichier = Dir
PJ = monFichier
Loop

strcommand = "C:\Program Files (x86)\Mozilla Thunderbird\thunderbird.exe"
strcommand = strcommand & " -compose " & "to='" & destinataire & "'"
strcommand = strcommand & "," & "subject=" & sujet & ","
strcommand = strcommand & "body='" & Chr(34) & body & Chr(34) & "'"
strcommand = strcommand & "," & "cc=" & cc
strcommand = strcommand & "," & "attachment='file:///" & PJ & "'"

Call Shell(strcommand, vbNormalFocus)

End Sub

Quelqu'un a une piste ?

Merci par avance,

Bonjour,

Un essai ...

Sub Envoyer_mail()
Dim destinataire As String
Dim sujet As String
Dim texte As String
Dim cc As String
Dim chemin As String
Dim monFichier As String

Dim PJ As String
Dim Pj2 As String

   destinataire = Range("C6")
   sujet = Range("C10")
   cc = Range("c8")
   texte = Range("b13")

   chemin = "C:\Users\user5\Desktop\Fichier\Envoi\"  ' <<< Chemin à adapter
   monFichier = Dir(chemin, vbNormal)

   PJ = "'" & chemin & monFichier & " , "
   Do While monFichier <> ""
      monFichier = Dir
      If monFichier <> "" Then PJ = PJ & "file:///" & chemin & monFichier & " , "
   Loop

   Do While Right(PJ, 2) = ", "
      PJ = Left(PJ, Len(PJ) - 2)
   Loop
   PJ = PJ & "'"

   ProgThunderbird = "C:\Program Files (x86)\Mozilla Thunderbird\thunderbird.exe"
   monCourriel = " -compose " & "to=" & destinataire & ",subject=" & sujet & ",body=" & texte & ",attachment=" & PJ

   Shell ProgThunderbird & monCourriel, vbNormalFocus
End Sub

ric

Bonjour,

Ouupppssss!!!!! Désolé, je me suis mêlé les doigts ... ce qui a créé ce doublon.

ric

Bonjour Ric,

Déjà un grand merci pour cette réponse. On y est presque !

Après essai, il y a un petit souci :

Cela envoi le dossier en lui même et non le contenu de celui-ci. Je vais essayer de bidouiller !

Bonjour,

Testé avec succès sur Thunderbird 60.2.1 et Excel 2016.

ric

En effet, j'avais oublié de remettre le "\" à la fin du chemin !

ça marche nickel, merci infiniment !!

Bonjour,

J'espère bien que ça fonctionne impec ...

J'ai tricoté longtemps pour trouver la recette secrète.

ric

J'imagine... C'est tout à ton honneur !

Merci encore,

lucas