Couleur série graph VBA

Bonjour à tous,

J'ai réaliser une macro qui me sert à mettre en forme les couleurs d'un graphique dynamique:

Mais j'ai un ptit bug

J'ai crée un graphique avec 6 séries, les 5 premières sont des histogrammes cumulés et la dernière ( la 6 eme) est une courbe.

Sub Couleur_graph10()
Dim i&
Dim couleur As Variant

Couleur1 = RGB(102, 204, 125)
Couleur2 = "RGB(155, 153, 0)"
Couleur3 = "RGB(204, 204, 204)"
Couleur4 = "RGB(255, 204, 0)"
Couleur5 = "RGB(153, 51, 51)"

ActiveSheet.ChartObjects("Graphique 10").Activate

For i = 1 To 5

    With ActiveChart.SeriesCollection(i)
        .Interior.Color = couleur(i)
    End With

Next

    With ActiveChart.SeriesCollection(6)
       .Border.Color = RGB(47, 49, 125)
    End With

End Sub

Quand j’exécute ce code j'ai un problème d’incompatibilité (erreur 13) sur la ligne ".Interior.Color = couleur(i)" à i=1 .

Voyez vous une erreur sur ce code qui fait que ça bug ?

Merci à vous

Bonjour,

Essaie ainsi:

Option Explicit

Sub Couleurs_graph10()
Dim cht As Chart
Dim Couleurs(1 To 5) As Long
Dim i As Long

    Couleurs(1) = RGB(102, 204, 125)
    Couleurs(2) = RGB(155, 153, 0)
    Couleurs(3) = RGB(204, 204, 204)
    Couleurs(4) = RGB(255, 204, 0)
    Couleurs(5) = RGB(153, 51, 51)

    Set cht = ActiveSheet.ChartObjects("Graphique 10").Chart

    For i = 1 To 5
        With cht.SeriesCollection(i)
            .Interior.Color = Couleurs(i)
        End With
    Next

    cht.SeriesCollection(6).Border.Color = RGB(47, 49, 125)

End Sub

Merci Jean-Éric, sa fonctionne nickel

Re,

Merci pour tes remerciements.