Image d'arrière plan et formes - débogage

Bonsoir,

Dans le fichier joint, une macro permet de sélectionner un objet (rectangle) selon sa valeur, où qu'il soit.

Lorsque j'insère un plan (image) nommé PLAN, je le positionne en arrière plan, derrière les formes (rectangles). La macro se met en mode débogage.

Chose étrange, si je mets l'image de fond en avant plan, la macro fonctionne.

Dans la macro Test, je ne sais pas où placer, une condition pour exclure l'image "PLAN", de la recherche :

Sub TEST()
    Dim f As Worksheet
    Dim s As Shape
    Dim texte As String
    For Each f In Sheets
        If f.Name <> "Accueil" And f.Name <> "Base de données" And f.Name <> "Plan de masse" Then
            texte = ActiveSheet.Shapes(Application.Caller).TextFrame.Characters.Text
            For Each s In f.Shapes
                If s.TextFrame.Characters.Text = texte Then
                    f.Activate
                    s.Select
                    Exit Sub
                End If
            Next
        End If
    Next
End Sub

Merci pour votre aide.

Bonjour,

Une proposition à étudier.

Cdlt.

Public Sub TEST()
Dim ws As Worksheet
Dim Shp As Shape
Dim shpText As String
    shpText = ActiveSheet.Shapes(Application.Caller).TextFrame.Characters.Text
    For Each ws In ActiveWorkbook.Worksheets
        Select Case ws.Name
            Case "Accueil", "Base de données", "Plan de masse", "Ne pas effacer", "Ne pas effacer 2":
            Case Else:
                For Each Shp In ws.Shapes
                    If Shp.Type <> msoPicture Then
                        If Shp.TextFrame.Characters.Text = shpText Then
                            ws.Activate
                            Shp.Select
                            Exit For
                        End If
                    End If
                Next
        End Select
    Next
End Sub

Merci Jean-Eric,

Cela fonctionne parfaitement.

Les deux macros qui tu m'as proposées me font gagner un temps précieux sur le fichier original. Elles permettront également l'insertion de lignes automatiques ou de formes, avec un nombre de manipulations réduit au strict minimum.

Cordialement

Bonne journée

Re,

C'est un petit cadeau de Noêl.

Bonnes fêtes de fin d'année.

A bientôt sur le forum...

Cdlt.

Bonnes fêtes également.

C'est un big cadeau de noël pour moi.