Remplissage automatique par VBA

Merci ce code aussi fonctionne très bien. Franchement merci les gars. je le conserve également.

Je voudrais pouvoir réaliser ceci maintenant :

dans "suivi chantier" si on rentre une date dans p, dans "recap chantier" un "oui " apparait dans la cellule "m"

et si dans "suivi chantier" si la cellule " p" est vide, dans "recap chantier" un "non " apparait dans la cellule "m"

Merci,

Re,

A tester !

Cdlt.

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim ws As Worksheet
Dim rw As Long
Dim rCell As Range

    Set ws = ActiveWorkbook.Worksheets("RECAP DOSSIER")

    If Not Application.Intersect(Target, Columns("B:E")) Is Nothing _
       And Target.Count = 1 Then
        ws.Range(Target.Address).Value = Target.Value
    End If

    If Not Application.Intersect(Target, Columns("F")) Is Nothing _
       And Target.Count = 1 Then
        rw = Target.Row
        Set rCell = ws.Range("I" & rw)
        If ws.Range("H" & rw) = "" Then ws.Range("H" & rw) = Date
        Select Case True
            Case UCase(Target.Value) = "NON"
                With rCell
                    .Value = "Non"
                    .Interior.Color = RGB(255, 0, 0)
                End With
            Case UCase(Target.Value) = "OUI"
                With rCell
                    .Value = "Oui"
                    .Interior.Color = xlNone
                End With
            Case Else
                With rCell
                    .Value = vbNullString
                    .Interior.Color = xlNone
                End With
        End Select
    End If

    If Not Application.Intersect(Target, Columns("P")) Is Nothing _
       And Target.Count = 1 Then
       rw = Target.Row
        Set rCell = ws.Range("M" & rw)
        Select Case True
            Case IsDate(Target.Value)
                rCell.Value = "Oui"
            Case Else
                rCell.Value = "Non"
        End Select
    End If

    Set rCell = Nothing: Set ws = Nothing

End Sub

j'ai fait un mixe des deux codes pour avoir exactement ce que je souhaite et cela fonctionne très bien.

Merci les gars pour votre aide.

j'ai le sourire car plus de souffrance......

Re,

N'oublie pas de clore le sujet.

Cdlt.