Recherche données, critère de plusieurs valeurs

Bonjour,

Mon fichier de travail est compose ainsi :

Un onglet chiffrage où on a pour chaque phase d’un projet, les différentes tâches qui seront exécutées, les noms des personnes qui les exécuteront, le nombre d’heures qui leur est attribués, la désignation des frais engendrés avec leurs montants estimés

Un onglet suivi où pour chaque tâche de chaque phase on a un tableau pour chaque personne qui retrouve le nombre d’heures prévisionnel (du chiffrage) et où on saisit un nombre d’heures réel effectué, même tableau pour les frais (coût prévisionnel retrouvé du chiffrage et réel saisi)

Un dernier onglet qui contient juste un tableau liste des différents frais

Mon problème est :

Dans mon onglet de suivi pour retrouvé automatiquement les heures prévisionnelles j’utilise cette formule :

=SOMMEPROD((chiffrage!$C$5:$C$10=suivi!$C$3)*(chiffrage!$B$5:$B$10=suivi!B5);chiffrage!$D$5:$D$10)

Je souhaiterais utiliser le même système pour retrouver la somme des frais engendrés par chaque tâche en utilisant la liste de l’onglet ressource

J’ai bêtement tenté =SOMMEPROD((chiffrage!$E$5:$E$10=ressource!$A$1:$A$5)*(chiffrage!$B$5:$B$10=suivi!B5);chiffrage!$F$5:$F$10)qui me retourne #N/A

Auriez-vous donc une idée pour régler ce problème en sachant que dans mes frais chiffrés apparaissent Machine A et Machine B que je ne veux pas prendre en compte et que si pour la même tâche j’ai deux frais différent dans le suivi doit s’afficher leur somme

Mon explication étant peut-être brouillon je joins un fichier exemple

Je vous remercie d’avance toute personne qui se penchera sur mon problème

19exemple1.xlsx (16.15 Ko)

Tu t'es un peu compliqué...

I5

=SUMPRODUCT((chiffrage!$B$5:$B$10=suivi!B5)*(chiffrage!$F$5:$F$10))

Merci pour cette réponse mais le problème avec cette solution c'est que les lignes machines sont inclues

=SUMPRODUCT(((chiffrage!$B$5:$B$10=suivi!B5)*(chiffrage!$F$5:$F$10))*(LEFT(chiffrage!E5:E10;7)<>"Machine"))

remplace sumproduct par sommeprod et left par gauche

Si je comprends bien avec cette solution on exclue les ligne dont la désignation commence par Machine?

Cela fonctionne dans mon petit fichier exemple mais cela n'ira pas pour mon fichier de travail car mes machines auront toutes des noms différents exemple bidon : machine A sera Imprimante et Machine B sera Scanner

C'est à cause de cette diversité que je souhaitais utiliser ma liste de l'onglet ressource

Tes matrices auront des longueurs différentes. Je ne pense pas que cela soit possible.

Tu vas devoir passer par une fonction personnalisée avec un boucle et une série de ifs.

Bonjour à vous deux,

Une formule matricielle du genre : (à valider simultanément par ctrl+alt+enter)

=SOMME((chiffrage!$F$5:$F$11)*(chiffrage!$B$5:$B$11=$B5)*(FREQUENCE(SI((chiffrage!$E$5:$E$10)<>TRANSPOSE(plage_exclusion);"";LIGNE($A$1:$A$6));LIGNE($A$1:$A$6))=0))

Dans la colonne C de l'onglet ressource, tu peux ajouter les éléments non pris en compte à la suite dans la cellule C3 par exemple (c'est dynamique donc ca prendra en compte les nouveaux éléments; dans ton cas les noms des machines).

Cette formule est un peu (beaucoup) indigeste mais normalement elle fonctionne. A toi de nous dire.

cdt

Bonjour et merci pour vos réponses

En cherchant encore un peu je me suis lancée dans cette formule qui fonctionne très bien

=SOMMEPROD((chiffrage!$B$5:$B$10=suivi!B5)*(NB.SI(ressource!$A$1:$A$5;chiffrage!$E$5:$E$10)>0)*chiffrage!$F$5:$F$10)

Bonjour,

Je te propose d'utiliser la fonction somme.si.ens() comme dans le tableau joint.

Cela marche avec une légère modification du tableau source où j'ai répété le n° de phase devant chaque ligne.

=SOMME.SI.ENS(chiffrage!$D$5:$D$21;chiffrage!$B$5:$B$21;suivi!$B5;chiffrage!$C$5:$C$21;suivi!C$3;chiffrage!$A$5:$A$21;suivi!$A$5)

dernière référence à modifier( $A$5 par $A$12) pour 2ème phase

Espérant que cela pourra te faire avancer dans l'élaboration de tes tableaux

Cordialement

FINDRH

16suivi-fab.xlsx (17.33 Ko)
Rechercher des sujets similaires à "recherche donnees critere valeurs"