Enregistrer une feuille Excel d'un classeur en .txt

Bonjour.

Je galère pour transformer une feuille d'un classeur excel en txt par l'intermédiaire d'une macro.

De plus je voudrais que ce nouveau document texte s'enregistre dans le dossier où se trouve mon classeur excel.

J'ai bien ce code que j'ai trouvé pour l'enregistrer sous le nom que je veux par l'intermédiaire d'inputbox, mais pour la suite je n'arrive pas à l'enregistrer dans le dossier voulu car il ne s'enregistre que dans mes documents par défaut.

Si quelqu'un avait une solution, merci d'avance.

Sub saveTxt()

    Dim wb As Workbook, ws As Worksheet
    Dim newWB As Workbook, newWS As Worksheet
    Dim strSaveAs As String
    On Error GoTo errSave
    Application.ScreenUpdating = False
    Set wb = ActiveWorkbook
    Set ws = ActiveSheet
    With ws
        .Copy
    End With
    Set newWB = ActiveWorkbook
    strSaveAs = InputBox("Entrer le nouveau nom de fichier.")
    With newWB
        .SaveAs strSaveAs, xlText
        .Close (False)
    End With
    wb.Activate
exitSave:
    Application.ScreenUpdating = True
    Exit Sub
errSave:
    MsgBox (Err.Number)
    MsgBox (Err.Description)
    Resume exitSave

End Sub

Bonjour,

Avec quelques modifications :

Sub saveTxt()

    Dim wb As Workbook, ws As Worksheet
    Dim newWB As Workbook, newWS As Worksheet
    Dim strSaveAs As String

    On Error GoTo errSave

    Application.ScreenUpdating = False

    Set wb = ActiveWorkbook
    Set ws = ActiveSheet

    ws.Copy

    Set newWB = ActiveWorkbook

    strSaveAs = InputBox("Entrer le nouveau nom de fichier.")

    If strSaveAs <> "" Then
        strSaveAs = wb.Path & "\" & strSaveAs
    Else
        GoTo exitSave
    End If

    With newWB

        .SaveAs strSaveAs, xlText
        .Close (False)

    End With

    wb.Activate

exitSave:
    Application.ScreenUpdating = True
    Exit Sub

errSave:
    MsgBox (Err.Number)
    MsgBox (Err.Description)
    Resume exitSave

End Sub

Merci beaucoup. C'était rapide.

Je viens de tester et cela marche très bien.

J'essayai d'enregistrer après l'avoir transformé en txt, mais pas avant.

Merci encore Theze.