VERSION 18
Private Sub Worksheet_Change(ByVal Target As Range)

  Dim dLig As Long, sTmp As String
  ' Si saisie de plus d'une cellule en même temps, on sort
  If Target.Count > 1 Then Exit Sub
  ' Modification dans la zone de saisie des critères
  If Not Intersect(Range("A2:I2"), Target) Is Nothing Then
    ' traitement de la valeur de la cellule
    sTmp = Target.Value
    ' Si vide on passe
    If sTmp <> "" Then
      ' Supprimer les étoiles si existantes
      sTmp = Replace(sTmp, "*", "")
      ' Les remettre en place
      sTmp = "*" & sTmp & "*"
      Application.EnableEvents = False
        Target.Value = sTmp
      Application.EnableEvents = True
    End If
    '
    ' Lancer le filtrage avancé
    With Sheets("Suivi Réglementation")
      dLig = .Cells.SpecialCells(xlCellTypeLastCell).Row
      On Error Resume Next
      .ShowAllData
      On Error GoTo 0
      dLig = .Cells.SpecialCells(xlCellTypeLastCell).Row
      With .Range("A3:I" & dLig)
        .AdvancedFilter Action:=xlFilterInPlace, CriteriaRange:=Range("A1:I2"), Unique:=False
      End With
    End With
  End If
End Sub
