Function ExportToMultiPagePDF(printAreas() As Range, pdfFileName As String) As Boolean
    Dim ws As Worksheet
    Dim i As Integer
    Dim success As Boolean
    Dim printAreaString As String

    On Error GoTo ErrHandler
    Application.ScreenUpdating = False

    Set ws = printAreas(1).Parent

    printAreaString = ""
    For i = LBound(printAreas) To UBound(printAreas)
        If Not printAreas(i) Is Nothing Then
            If printAreaString = "" Then
                printAreaString = printAreas(i).Address
            Else
                printAreaString = printAreaString & "," & printAreas(i).Address
            End If
        End If
    Next i

    ws.PageSetup.printArea = printAreaString

    With ws.PageSetup
        .Zoom = False
        .FitToPagesWide = 1
        .FitToPagesTall = 1
    End With

    ws.ExportAsFixedFormat Type:=xlTypePDF, Filename:=pdfFileName, Quality:=xlQualityStandard, _
                           IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False

    success = True
    ExportToMultiPagePDF = success

    ws.PageSetup.printArea = ""
    Application.ScreenUpdating = True
    Exit Function

ErrHandler:
    MsgBox "Erreur lors de l'exportation en PDF: " & Err.Description
    ExportToMultiPagePDF = False
    Application.ScreenUpdating = True
End Function