Sélectionner une cellule après sélection dans une ListBox

Bonjour,

Je cherche depuis un moment à sélectionner une cellule après sélection dans une ListBox dynamique qui n’affiche pas toute les lignes car avec un if colonne 1 = toto

La ListBox me montre les 5 valeurs de de la colonne 2 pour lesquelles j’ai toto en colonne 1

Après l’utilisation de ListBox1.ListIndex + 2 ne prend pas en considération que pas toute les valeurs de la colonne s’affiche dans la ListBox.

Tout ce que je veux c’est sélectionner/activer la cellule que je sélectionne dans la ListBox pour travailler les données sur cette ligne

Si quelqu’un pouvait m’aider se serrait super !

Voici le code :

Private Sub UserForm_Initialize()

Dim rngName As Range

Dim ws As Worksheet

Dim i As Integer

Set ws = Worksheets("ABC")

For i = 1 To ws.Cells(ws.Rows.Count, 1).End(xlUp).Row Step 1

If ws.Cells(i, 2).Value <> vbNullString And ws.Cells(i, 1).Value = "toto" Then Me.ListBox1.AddItem ws.Cells(i, 2).Value

Next i

End Sub

Private Sub ListBox1_Click()

Sheets("ABC").Cells(ListBox1.ListIndex + 2, 2).Select

End Sub

Bonjour et bienvenue sur le forum

canthagar a écrit :

La ListBox me montre les 5 valeurs de de la colonne 2

Ce serait bien si elle nous les montrait aussi !

Joint donc ton fichier !

Bye

Bonjour,

Je ne suis pas sûr de tout comprendre

Tu veux pouvoir sélectionner les cellules en colonne B où se trouve "toto" en colonne A ? Si c'est le cas, il te faut utiliser un tableau pour stocker les numéros de lignes :

Dim Tbl() As Long

Private Sub UserForm_Initialize()

Dim rngName As Range
Dim ws As Worksheet
Dim i As Integer
Dim J As Long

Set ws = Worksheets("ABC")

For i = 1 To ws.Cells(ws.Rows.Count, 1).End(xlUp).Row Step 1

    If ws.Cells(i, 2).Value <> vbNullString And ws.Cells(i, 1).Value = "toto" Then

        Me.ListBox1.AddItem ws.Cells(i, 2).Value

        J = J + 1
        ReDim Preserve Tbl(1 To J)
        Tbl(J) = ws.Cells(i, 2).Row

    End If

Next i

End Sub

Private Sub ListBox1_Click()

    Sheets("ABC").Cells(Tbl(ListBox1.ListIndex + 1), 2).Select

End Sub

Hervé.

Hello Hervé,

Ta technique pourrait fonctionner, j’ai juste encore une erreur :

La ligne ReDim Preserve Tbl(1 To J)

Il me dit : Variable not defined

Que faut-t-il que je mette ?

Merci encore pour ton aide

oups pas vu la première ligne!

Merci beaucoup pour l’aide c’est génial après des heures et des heures de recherche tu me donnes la solution en quelques minutes !

Milles merci !