Dupliquer une ligne sur une autre feuille

Bonjour,

Je viens vers vous espérant trouver une solution à mon problème.

Sur le fichier ci-joint et sur la feuille "Menu", quand je clique sur le bouton "Table Emetteurs" je veux que le contenu des cellules de la colonne "C" à partir de "C5" soit copier et dupliquer 3 fois dans la colonne "A" et 3 fois dans la colonne "B" avec les suffixes "_F0", "_F1" et "_F2" et dans la colonne "C" la valeur "True" pour chaque ligne dans la feuille "Trame émetteurs".

Dans la feuille ""Trame émetteurs" j'ai rempli, pour illustration, ce que je souhaite avoir avec la macro.

Je vous remercie d'avance pour votre retour.

Bien cordialement;

Bonjour,

Une proposition à tester ...

Sub Copie_Emetteurs()
Dim WsS As Worksheet, WsC As Worksheet
Dim DerLigS As Long, LigneAjoutC As Long
Dim Plage As Range, Cel As Range
Dim i As Integer
    Set WsS = Worksheets("Menu")
    Set WsC = Worksheets("Trame émetteurs")
    DerLigS = WsS.Range("C4").End(xlDown).Row
    If DerLigS = WsS.Rows.Count Then Exit Sub
    Set Plage = WsS.Range("C5:C" & DerLigS)
    Application.ScreenUpdating = False
    For Each Cel In Plage
        LigneAjoutC = WsC.Range("A" & Rows.Count).End(xlUp).Row + 1
        For i = 0 To 2
            WsC.Range("A" & LigneAjoutC + i) = Cel.Value
            WsC.Range("B" & LigneAjoutC + i) = Cel.Value & "_F" & i
            WsC.Range("C" & LigneAjoutC + i) = True
            WsC.Range("H" & LigneAjoutC + i) = Cel.Offset(, 3).Value
        Next i
    Next Cel
    WsC.Activate
    Application.ScreenUpdating = True
End Sub

Cordialement.

gyrus,

Merci beaucoup pour ton retour, c'est exactement ce que je cherche !

Bonne soirée

Rechercher des sujets similaires à "dupliquer ligne feuille"