Erreur de compilation dans le module caché : module2
Bonsoir,
J'ai finalisé mon fichier Excel qui comporte plusieurs macro et un userform.
Chez moi tout fonctionne.
Je l'ai transmis à un collègue et celui-ci m'indique avoir un message d'erreur :
"Erreur de compilation dans le module caché : module2"
Le module2 de mon fichier correspond à une macro pour l'envoi de mon fichier en pdf par mail.
Je ne comprends pas le problème.
Pourriez-vous m'aider ?
Merci d'avance.
Bonjour Loic, le forum
On aimerais bien t'aider mais la on a aucune idée du probleme
Peut on voir le code du module caché?
Noter que l'envoi de mail peut necessiter l'ajout de references. Verifier sur le second poste si pas de reference manquante.
Cdt
A
Voici le code :
Sub envoi_pdf_mail()
Dim ret As Integer
ret = MsgBox("Envoi du formulaire par mail." & Chr(10) & Chr(10) & "Voulez-vous continuer ?", vbYesNo + vbQuestion, "Envoyer par mail")
If ret = vbNo Then
Exit Sub
Else
Dim olApp As Outlook.Application
Dim olMail As MailItem
Dim CurFile As String
Set olApp = New Outlook.Application
Set olMail = olApp.CreateItem(olMailItem)
CurFile = ThisWorkbook.Path & "\" & "fichier - " & Sheets("fichier").Range("A10").Value
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=CurFile, _
Quality:=xlQualityStandard, IncludeDocProperties:=False, IgnorePrintAreas:=False, _
OpenAfterPublish:=False
With olMail
.Display '.Send
.To = "mail@mail.fr"
.CC = ""
.Subject = "Envoi du fichier"
.HTMLBody = "<html><body>Bonjour," & "<br><br>" & "Veuillez trouver en pièce jointe le fichier." & "<br><br>" & "Vous souhaitant bonne réception." & "<br><br>" & "Cordialement," & "</html></body>" & .HTMLBody
.Attachments.Add ThisWorkbook.Path & "\" & "fichier - " & Sheets("fichier").Range("A10").Value & ".pdf"
End With
Set olMail = Nothing
Set olApp = Nothing
Kill ThisWorkbook.Path & "\" & "fichier - " & Sheets("fichier").Range("A10").Value & ".pdf"
End If
End Sub
Pour rappel ce code fonctionne parfaitement bien sur mon PC (Excel 2016)
La référence Outlook library est bien présente
Bonsoir,
essaie ceci, code qui permet de s'affranchir de la référence à la bibliothèque outlook (probablement pas la même version sur vos 2 ordinateurs)
Sub envoi_pdf_mail()
Dim ret As Integer
ret = MsgBox("Envoi du formulaire par mail." & Chr(10) & Chr(10) & "Voulez-vous continuer ?", vbYesNo + vbQuestion, "Envoyer par mail")
If ret = vbNo Then
Exit Sub
Else
Dim olApp As Object
Dim olMail As Object
Dim CurFile As String
Set olApp = CreateObject("outlook.application")
Set olMail = olApp.CreateItem(0)
CurFile = ThisWorkbook.Path & "\" & "fichier - " & Sheets("fichier").Range("A10").Value
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=CurFile, _
Quality:=xlQualityStandard, IncludeDocProperties:=False, IgnorePrintAreas:=False, _
OpenAfterPublish:=False
With olMail
.Display '.Send
.To = "mail@mail.fr"
.CC = ""
.Subject = "Envoi du fichier"
.HTMLBody = "<html><body>Bonjour," & "<br><br>" & "Veuillez trouver en pièce jointe le fichier." & "<br><br>" & "Vous souhaitant bonne réception." & "<br><br>" & "Cordialement," & "</html></body>" & .HTMLBody
.Attachments.Add ThisWorkbook.Path & "\" & "fichier - " & Sheets("fichier").Range("A10").Value & ".pdf"
End With
Set olMail = Nothing
Set olApp = Nothing
Kill ThisWorkbook.Path & "\" & "fichier - " & Sheets("fichier").Range("A10").Value & ".pdf"
End If
End SubBonjour,
Merci beaucoup pour cette correction. ça fonctionne parfaitement.
J'ai juste en complément décocher la référence à Outlook car le message d'erreur était encore présent.
Merci encore.