Recherche index plusieurs criteres
Bonjour,
J'ai réalisé une fonction INDEX qui me permet de balayer un tableau afin d'en sortir les données souhaitées, toutefois, à présent il me faudrait filtrer ces données suivant un second critère, et c'est là que je pêche ...
Voici ma formule de départ :
{=SIERREUR(INDEX([Projection.xlsm]Traitement!$C14:$C5011;PETITE.VALEUR(SI(B23=[Projection.xlsm]Traitement!$Q:$Q;LIGNE([Projection.xlsm]Traitement!$Q:$Q)-MIN(LIGNE([Projection.xlsm]Traitement!$Q14))+1;"");$A23));"")}
J'ai donc ajouté mon second critère comme suit, mais cela ne fonctionne pas, dois-je utiliser la fonction EQUIV ? j'ai vu qu'elle me permettait de répondre à mon besoin, mais combiné avec la suite de ma formule, notamment "PETITE VALEUR", cela ne répond plus.
Ma tentative :
{=SIERREUR(INDEX([Projection.xlsm]Traitement!$C3:$C5000;PETITE.VALEUR(SI(ET(B12=[Projection.xlsm]Traitement!$Q:$Q;"TEST"=[Projection.xlsm]Traitement!$L:$L);LIGNE([Projection.xlsm]Traitement!$Q:$Q)-MIN(LIGNE([Projection.xlsm]Traitement!$Q3))+1;"");$A12));"")}
Merci d'avance pour votre aide,
Bonne journée,
Luciole
J'ai oublié de joindre le fichier, cela peut-être vous aider.
De nouveau merci pour votre aide.
Luciole
Bonjour Luciole (c'est mimi
Il y a des choses qui ne sont pas claires:
- tu utilises A12 (de manière un peu curieuse !?) et dans le fichier que tu as transmis, cette cellule est vide
- tu utilises B12 comme critère, mais cette colonne-là est vide aussi
- je ne comprends pas l'utilisation que tu fais de
... un MIN, appliqué à un seul argument - qu'est supposée faire cette formule ?
Attention:
Oui, en réalité j'ai simplifié au maximum mon fichier, et du coup j'ai supprimé quelques colonnes qui se retrouvent dans mes formules, oups
L'idée de ma formule est de balayer l'ensemble du fichier (équivalent à une boucle) pour récupérer les infos qui m'intéressent.
Je te le transmets de nouveau, en espérant que cela soit plus clair.
J'ai mis le cas d'application au propre, avec le détail des 2 formules que je souhaite combiner en une.
Encore merci,
Bonne soirée,
Luciole
Bonsoir,
Je ne sais pas si j'ai compris ... essaie, en G3 de la feuille RECHERCHE:
=SIERREUR(INDEX(Traitement!$C$3:$C$3000;PETITE.VALEUR(SI((Traitement!$Q$3:$Q$3000=Recherche!B3)*(Traitement!$L$3:$L$3000="TEST");LIGNE(Traitement!$Q$3:$Q$3000)-2);LIGNES($1:1)));"")Valider avec Ctrl+Shift+Enter, comme précédemment
Ah oui c'est ça ! il fallait multiplier les critères du coup, et ne pas tenter avec le "ET".
Super merci beaucoup !
Du coup, je réduirai la table comme tu me l'as conseillé, afin de ne pas balayer l'ensemble de la feuille Excel.
J'en profite pour te poser une autre question
Disons que j'ai 3 semaines à traiter en parallèle (colonnes B,C,D), toutefois, comment anticiper le nombre d'éléments qui vont sortir, comment puis-je sortir les données en automatique, sans tirer la formule au max afin d'être sûre de n'en oublier aucune.
Je ne sais pas si cela est clair.
Encore merci.
Euh ... Honnêtement ?Disons que j'ai 3 semaines à traiter en parallèle (colonnes B,C,D), toutefois, comment anticiper le nombre d'éléments qui vont sortir, comment puis-je sortir les données en automatique, sans tirer la formule au max afin d'être sûre de n'en oublier aucune.
Je ne sais pas si cela est clair.
Tu cherches une formule pour créer, en colonne B, autant d’occurrences de "S31" qu'il y en a en colonne Q de la feuille Traitement ? Si c'est ça, essaie, en B3:
=SI(NB.SI(Traitement!$Q$3:$Q$3000;"S31")>=LIGNES($1:1);"S31";"")Oui c'est exactement ça, toutefois, après avoir copié la formule, aucune cellule ne s'auto remplie ..
Il me suffisait juste d'insérer la formule en B3 ?
Merci,
Luciole
Mouais !
J'ai essayé dans le même, mais rien ne se passe ...
Qu'est-ce donc qu'il y aurait de différent entre ce que tu as fait et le fichier en annexe ?
Ihi
Non mais en fait je pense qu'il me manque une info ... tu tires la formule ou pas ? sur les lignes 4 et suivantes ?
On est obligé de recopier la formule vers le bas, aussi loin que nécessaire, en précisant que rien ne doit s'afficher dans le cas où on dépasserait le nombre d'occurrences de "S31" en feuille "Traitement".
Seule une macro permettrait de n'inscrire que x mentions "S31"
Ça répond à ta question ?
Oui ça parait logique, et en effet, ça répond à ma question.
Je te remercie d'avoir répondu à ma problématique de départ,
Bonne continuation.
Luciole