Envoie par mail et selection

Bonjour quelqu'un aurai le bout de code qui permet d'envoyer par mail?

Et j'ai une question est ce que ca serais possible: avoir une plage de cellule ou un tableau, et quand je selectionne une cellule elle de celui ci un "x" apparaît et quand la cellule contient déjà un "x" et que je reclique dessus il disparait, un peu le meme système qu'un bouton poussoire mais sans bouton

Bonjour,

une question à la fois ...

naubin1 a écrit :

Bonjour quelqu'un aurai le bout de code qui permet d'envoyer par mail?

Option Explicit
Sub envoi()

Dim messagerie As Object
Dim email As Object

Set messagerie = CreateObject("Outlook.Application")

        Set email = messagerie.CreateItem(0)

        With email
            .to = "mettre ici adresses email"
            .Subject = "mettre ici le titre du mail"
            .body = "mettre ici le contenue"
            .ReadReceiptRequested = True
            .display ' à remplacer par .send si ok
        End With

        Set email = Nothing

Set messagerie = Nothing

End Sub

naubin1 a écrit :

Et j'ai une question est ce que ca serais possible: avoir une plage de cellule ou un tableau, et quand je selectionne une cellule elle de celui ci un "x" apparaît et quand la cellule contient déjà un "x" et que je reclique dessus il disparait, un peu le meme système qu'un bouton poussoire mais sans bouton

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
Application.EnableEvents = False
If Target.Value = "x" Then
    Target.Value = ""
    GoTo fin
End If
If Target.Value = "" Then Target.Value = "x"
fin:
Application.EnableEvents = True
End Sub

je test tout ca et je te dit quoi je te remercie

pour

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
Application.EnableEvents = False
If Target.Value = "x" Then
    Target.Value = ""
    GoTo fin
End If
If Target.Value = "" Then Target.Value = "x"
fin:
Application.EnableEvents = True
End Sub

je l'éssaie mais ca ne fonctionne pas, je l'ai bien collé dans feuill2(Grille) pourtant

Et petite question cest possible que ca soit en gmail?

naubin1 a écrit :

je l'éssaie mais ca ne fonctionne pas, je l'ai bien collé dans feuill2(Grille) pourtant

c'est un clic droit !

naubin1 a écrit :

Et petite question cest possible que ca soit en gmail?

pour gmail, utilise CDO, regarde ici

https://www.youtube.com/watch?v=pFl7W8d7d4M

naubin1 a écrit :

Et petite question cest possible que ca soit en gmail?

Pour les croix c'est niquel !,

pour l'émail j'ai un msg d'érreur :le message n'a pas pu être envoyé vers le serveur SMTP. le code d’erreur de transport est 0x80040217. la réponse du serveur était not available

Je ne peux t'aider, j'ai essayé en ce qui me concerne et cela a fonctionné impeccable !

dans .HTMLBody = "Write your complete HTML Page"

je dois mettre quoi?

.TextBody ou bien .HTMLBody

Le premier nécessite juste du texte.

Le second est plus "riche"

naubin1 a écrit :

dans .HTMLBody = "Write your complete HTML Page"

je dois mettre quoi?

Poste un bout de fichier ou dis nous ce que tu veux écrire ...

bah j'ai pas vraiment d'exemple... j'ai besoin de ca pour envoyer un fichier en pièce jointe qui correspond a des stats après ca peut venir d'une boite mail que je crée vers des collègues

donc from moi@gmail.com

to lapersonneconcerné@blabla-group.com

naubin1 a écrit :

j'ai besoin de ca pour envoyer un fichier en pièce jointe qui correspond a des stats après ca peut venir d'une boite mail que je crée vers des collègues

ok

dans ce cas, dans le code tu modifies le code comme ceci

With NewMail
  .Subject = "mettre un titre"
  .From = ""
  .To = ""
  .CC = ""
  .BCC = ""
  .TextBody = "Veuillez trouver ci-joint bla bla bla "
  .AddAttachment "C:\Users\Michel\Downloads\test.xlsx"
End With

j'ai ajouté les adresse dans from et to

from: test.numeero.un@gmail.com

to:nicolas-aubin@laposte.net

le message n'a pas pu être envoyé vers le serveur SMTP. le code d’erreur de transport est 0x80040217. la réponse du serveur était not available

peut être parce que je dois mettre les mdp de l'adresse mail?

Sub SendEmailUsingGmail()

    On Error GoTo Err

    Dim NewMail As Object
    Dim mailConfig As Object
    Dim fields As Variant
    Dim msConfigURL As String

    Set NewMail = CreateObject("CDO.Message")
    Set mailConfig = CreateObject("CDO.Configuration")

    ' load all default configurations
    mailConfig.Load -1

    Set fields = mailConfig.fields
With NewMail
  .Subject = "résultat "
  .From = "test.numero.un.@gmail.com"
  .To = "nicolas-aubin@laposte.net"
  .CC = ""
  .BCC = ""
  .TextBody = "Veuillez trouver ci-joint bla bla bla "
  .AddAttachment "H:\lalala\Bande TDM.xlsx"
End With

    msConfigURL = "http://schemas.microsoft.com/cdo/configuration"

    With fields
        'Enable SSL Authentication
        .Item(msConfigURL & "/smtpusessl") = True

        'Make SMTP authentication Enabled=true (1)
        .Item(msConfigURL & "/smtpauthenticate") = 1

        'Set the SMTP server and port Details
        .Item(msConfigURL & "/smtpserver") = "smtp.gmail.com"
        .Item(msConfigURL & "/smtpserverport") = 465
        .Item(msConfigURL & "/sendusing") = 2

        'Set your credentials of your Gmail Account
        .Item(msConfigURL & "/sendusername") = "prenom.nom@gmail.com"
        .Item(msConfigURL & "/sendpassword") = "********"

        'Update the configuration fields
        .Update

    End With
    NewMail.Configuration = mailConfig
    NewMail.Send
    MsgBox ("OK, c'est parti !")

Exit_Err:

    Set NewMail = Nothing
    Set mailConfig = Nothing
    End

Err:
    Select Case Err.Number

    Case -2147220973  'Could be because of Internet Connection
        MsgBox " Could be no Internet Connection !!  -- " & Err.Description

    Case -2147220975  'Incorrect credentials User ID or password
        MsgBox "Incorrect Credentials !!  -- " & Err.Description

    Case Else   'Rest other errors
        MsgBox "Error occured while sending the email !!  -- " & Err.Description
    End Select

    Resume Exit_Err

End Sub

Il faut mettre

        .Item(msConfigURL & "/sendusername") = "prenom.nom@gmail.com"
        .Item(msConfigURL & "/sendpassword") = "********"

une VRAIE adresse gmail et le VRAI mot de passe de messagerie