Concaténer deux colonne

Salut

je veux chercher des références dans deux feuilles et après si on trouve une correspondance de concaténer deux colonnes mais le problème que les colonnes sur lesquels on effectue la recherche ne sont pas au même ordre et le nombre des colonnes sont différents.

j'ai réaliser ce code mais il chercher la position des colonnes mais non le contenu.Merci d'avance

Sub Search()

Dim F1 As Worksheet
Dim F2 As Worksheet
Dim res As String

Dim plage As Range
Dim C As Range

Set F1 = Worksheets("April")
Set F2 = Worksheets("Mai")

Set plage = F2.Range("G2", F2.Range("G65536").End(xlUp))

For Each C In plage
        Set re = F1.Range("G:G").Find(Trim(C.Value), LookAt:=xlPart)
        If re Is Nothing Then
        F2.Cells(C.Row, "Z") = "N"
        Else

         F2.Cells(C.Row, "B") = F2.Cells(C.Row, "B")
         F2.Cells(C.Row, "Z") = F1.Cells(C.Row, "C") & F2.Cells(C.Row, "C")

    End If
Next C

End Sub

Bonjour,

C'est ça que tu cherches à faire ?

Sub Search()

    Dim F1 As Worksheet
    Dim F2 As Worksheet
    Dim plage As Range
    Dim C As Range
    Dim Re As Range
    Dim res As String

    Set F1 = Worksheets("April")
    Set F2 = Worksheets("Mai")

    Set plage = F2.Range("G2", F2.Range("G65536").End(xlUp))

    For Each C In plage

            Set Re = F1.Range("G:G").Find(Trim(C.Value), , xlValues, xlPart)

            If Re Is Nothing Then

                F2.Cells(C.Row, "Z") = "N"

            Else

                F2.Cells(C.Row, "Z").Value = F1.Cells(Re.Row, "C").Value & F2.Cells(C.Row, "C").Value

        End If

    Next C

End Sub

oui ça fonctionne très bien. merci beaucoup tu m'a sauvé

Rechercher des sujets similaires à "concatener deux colonne"