Sélectionner et Importer fichier txt dans Excel

Question

Complètement débutant, quasiment sans notion, je souhaiterais, dans un classeur excel : aller sélectionner un fichier txt sur des supports variables DD ou USB (exemple de fichier à importer en pièce jointe) importer ce fichier txt dans un classeur excel de la façon suivante : - les 2 premiers caractères en format nombre entier - les 8 caractères suivants en format txt - les 8 caractères suivants en format txt - les 4 caractères suivants en format heure - les 4 caractères suivants en format heure - les 7 caractères suivants (O/N) dans 7 colonnes différentes en les transformant en O=1 et N=0 - les 6 caractères suivants en format txt - les 6 caractères suivants en format txt Je suis conscient de faire faire le travail, mais, en étudiant ensuite la macro, j'espère pouvoir me lancer. A bientôt 54 ans, j'ai beau aller voir dans différents forums, j'ai un peu de mal à me lancer Grand merci par avance...

MFerrand · Answer

A toi de commencer par fournir un fichier texte dont le contenu répond à ce que tu demandes ! Cordialement...

MFerrand · Answer

La macro ouvre le fichier txt, le traite, place le résultat sur une feuille.

Pour finaliser, il me faudrait avoir les éléments d'environnement et que tu précises le processus...

Je propose un classeur dédié au traitement : tu notes dans une cellule le nom du fichier, dans une autre le chemin du dossier, et la macro opère à partir de ces informations.

De même, il faudrait savoir si chaque fichier traité ira dans un classeur spécifique ou un classeur les regroupant d'une part.

Et sous quel nom l'enregistrer et dans quel dossier (chemin)

Eventuellement aussi si tu souhaites pouvoir traiter plusieurs fichiers txt simultanément.

Cordialement.

Regarde aussi si le résultat en Feuil1 te convient ou si tu souhaites une mise en forme particulière (là je me suis contenté d'un ajustement automatique des largeurs de colonnes).

234p45c4l-traitementtxt.xlsm (24.96 Ko)

MFerrand · Answer

Résumons-nous : - Une boîte de dialogue d'ouverture de fichier où tu iras toi-même sélectionner le fichier à ouvrir... OK ! - Pour l'enregistrement : il conviendrait de préciser : • soit on ne l'enregistre pas, on le l'affiche et à toi de poursuivre ! • soit on l'enregistre, il faut donc noter quelque part son nom et le chemin du dossier... • ...ou même mécanisme qu'à l'ouverture, boîte de dialogue et c'est toi qui ira désigner le dossier et indiquera le nom ! Les jours je suppose que ce sont les 7 colonnes 1/0 qui les indiquent... Si les heures indiquent un horaire de début et fin d'intervention, on peut effectivement te comptabiliser celles situées dans une plage déterterminée ou les signaler dans la 15e colonne... (Il conviendrait de préciser si c'est "à cheval sur 2 jours &#91;soit commencée avant minuit et terminée après&#93; ou située dans la plage horaire 20:00/05:00.) Si la mise en forme te convient, pas de raison d'y retoucher. Je noterai quelques commentaires dans le code, qui te permettront de te repérer, à avoir quel fragment de code fait quoi... mais ne compte pas trop pouvoir introduire des ajouts ou modifications sans une connaissance minimale des rudiments de VBA. Le code n'est très long (si tu as eu la curiosité d'aller voir) mais justement parce qu'il repose sur des instructions VBA qu'il convient d'apprendre pour s'en servir (boucles, tableaux, instructions conditionnelles...) Cordialement...

MFerrand · Answer

Voilà donc la macro définitive, version commentée :

Sub TraiterTxt()
    Dim Tbl(), Ftx, Stx, Ltx$, Utx$, n%, i%, ni%, hd, hf, hh
    'Sélection fichier TXT
    Ftx = Application.GetOpenFilename("Text Files (*.txt), *.txt", , "Sélectionnez un fichier")
    If Ftx = False Then Exit Sub
    'Heures début et fin de plage d'intervention Nuit
    hd = TimeValue("20:00:00"): hf = TimeValue("05:00:00")
    Application.ScreenUpdating = False
    'Ouverture fichier sélectionné
    With Workbooks.Open(Ftx).Worksheets(1)
        'dimensionnement texte sur feuille 1 (dernière ligne occupée)
        n = .Cells(.Rows.Count, 1).End(xlUp).Row
        'dimensionnement tableau résultat (n lignes, 14 colonnes)
        ReDim Tbl(1 To n, 13)
        'tableau des rangs des caractères débutant chaque fragment d'une ligne du texte
        ' à mettre dans une colonne distincte, la longueur de chaque fragment est défini
        ' par la différence avec le rang du suivant, le dernier rang ne sert qu'à définir
        ' la longueur du dernier fragment
        Stx = Array(1, 3, 11, 19, 23, 27, 28, 29, 30, 31, 32, 33, 34, 40, 46)
        'boucle sur chaque ligne de texte
        For i = 1 To n
            'recueil de la ligne de texte
            Ltx = .Cells(i, 1)
            'boucle d'extraction des fragments (14 fragments)
            For j = 0 To 13
                'extraction de chaque fragment
                Utx = Mid(Ltx, Stx(j), Stx(j + 1) - Stx(j))
                'traitement de chaque fragment selon sa position dans le texte
                Select Case j
                    'valeurs O ou N à remplacer par 1 ou 0
                    Case 5 To 11
                        Tbl(i, j) = IIf(Utx = "O", 1, 0)
                    'valeurs texte : on fait précéder un chiffre par une apostrophe
                    ' pour éviter conversion automatique en nombre par Excel
                    Case 1, 2, 12, 13
                        Tbl(i, j) = IIf(IsNumeric(Left(Utx, 1)), "'" & Utx, Utx)
                    'valeurs à convertir en heures (insertion du séparateur horaire (:))
                    Case 3, 4
                        Tbl(i, j) = Left(Utx, 2) & ":" & Right(Utx, 2)
                    'valeur numérique
                    Case 0
                        Tbl(i, j) = CInt(Utx)
                End Select
            Next j
            'récupération de l'heure de début
            hh = TimeValue(Tbl(i, 3))
            ' on comptabilise si cette heure se situe en plage Nuit
            If hh >= hd Or hh < hf Then ni = ni + 1
        Next i
    End With
    'Fermeture fichier texte
    ActiveWorkbook.Close False
    With ThisWorkbook
        'Ajout d'une feuille au classeur de traitement
        'on dimensionne la plage résultat (n ligne, 14 colonnes)
        With .Worksheets.Add(before:=Worksheets(1)).Range("A1").Resize(n, 14)
            'on affecte le tableau résultat à cette plage
            .Value = Tbl
            'on opère un ajustement automatique des largeurs de colonnes
            .Columns.AutoFit
            '2 lignes sous le texte traité, on indique le nombre d'interventions débutant en Nuit
            .Cells(n + 2, 1) = "Nb d'interventions débutant entre " & Format(hd, "hh""h""mm") _
             & " et " & Format(hf, "hh""h""mm") & " : " & ni
        End With
        'on exporte la feuille résultat dans un nouveau classeur
        .Worksheets(1).Move
    End With
End Sub

Conformément à tes dernières spécifications : sélection du fichier à traiter au moyen d'un boîte de dialogue, définition des heures Nuit dans des variables (si elles changent, on modifiera l'initialisation de hd et hf en début de macro), comptabilisation au cours du traitement des heures de début situées en plage Nuit, fermeture du fichier texte en fin de traitement, résultat dans un nouveau classeur (obtenu par ajout de feuille pour y affecter résultat et export de cette feuille dans un nouveau classeur) non enregistré.

Cordialement.

69p45c4l-traitementtxt.xlsm (22.13 Ko)

MFerrand · Answer

Fichier réaménagé...

MFerrand · Answer

Avant de regarder quoi que ce soit !

Ton dernier schéma indiquait : "LU/MA" en col. F et ainsi de suite pour les colonnes suivantes. Je m'y suis fié.

Ta directive antérieure indiquait de ne tenir compte que des heures de début, ce que j'a fait.

Je ne sais pas (et ne veut pas savoir !) ce que sont les opérations de lundi 20h00 à 23h59 et mardi 00h00 à 05h00 ! Il me faut seulement une condition définie exhaustivement en termes logiques à partir des heures en colonnes D et E et des 1 en colonnes F à L (pour un résultat porté en bas desdites colonnes F à L).

Cordialement.

MFerrand · Answer

Réaliser une description en termes de logique n'est certainement pas un exercice facile, et je ne prétendrai d'ailleurs pas être moi-même en mesure de le réaliser toujours de façon ne serait-ce que satisfaisante ! Mais je suis tout de même toujours un peu surpris de voir la majorité de mes correspondants reculer devant l'obstacle ! C'est tout de même un exercice éminemment instructif, qui permet entre autres de s'extraire de l'examen d'un problème pour le voir en quelque sorte de l'extérieur... Sans épiloguer plus... Sub InterventionsNuit() Dim hn(6) As Integer, hd, hf, hh, n%, i%, j%, k% hd = TimeValue("20:00:00"): hf = TimeValue("05:00:00") With ActiveSheet If IsEmpty(.Range("A1")) Then Exit Sub n = .Cells(.Rows.Count, 1).End(xlUp).Row For i = 1 To n hh = .Cells(i, 4) If hh &gt;= hd Or hh &lt; hf Then k = IIf(hh &gt;= hd, 6, 7) For j = 6 To 12 If .Cells(i, j) = 1 Then hn(j - k) = hn(j - k) + 1 Next j End If Next i .Cells(n + 2, 1) = "Nb d'interventions " &amp; Format(hd, "hh""h""mm") &amp; "-" _ &amp; Format(hf, "hh""h""mm") With .Cells(n + 2, 6).Resize(, 7) .Value = hn .Columns.AutoFit End With End With End Sub vois ce que donne cette version : les modifications par rapport à la précédente sont surlignées. Cordialement...

MFerrand · Answer

Je n'ai point conçu de soupçon de cet ordre ...

thunder23 · Answer

Bonjour MFerrand, bonjour le forum, Ton code m'intéresse beaucoup mais je voudrais qu'il prenne tout le fichier .txt comme il est mais que ça soit mis sur une feuille spécifique dans le classeur, aurais-tu une piste? Merci Cdlt...