Macro Cacher Ligne
Bonjour,
Je vous explique,
Le but dans un premier temps serai de créer une macro qui pourrais s'adapter sur plusieurs fichiers Excel : rajouter automatiquement les deux colonnes présente en rouge du fichier joint sur un fichier quelconque.
Dans un 2nd temps, que lorsque on clique sur la case « valider », il y est une boite de dialogue qui apparaisse dans lequel on remplirai le champs « Commentaires ». Une fois la boite de dialogue fermé par un bouton « OK », la ligne se cacherais automatiquement.
Voilà voilà, j'espère que j'ai bien expliqué ma demande
Merci de votre aide,
Joe
Bonjour,
voici un exemple, je ne sais pas de quel façon vous avez prévu de réafficher les lignes, mais j'ai ajouter une macro pour le cas,
Sub Caseàcocher_Cliquer()
Nom = Application.Caller
rw = ActiveSheet.Shapes(Nom).TopLeftCell.Row
Cells(rw, 8) = AjoutCommentaire 'colonne H
ActiveSheet.Rows(rw).Hidden = True
End Sub
Function AjoutCommentaire()
Dim Message, Title
Message = "Entrez un commentaire"
Title = "Commentaire" ' Définit le titre.
AjoutCommentaire = InputBox(Message, Title)
End Function
Sub AjoutCaseàcocher()
Dim Nom As String, LastRw As Long, i As Long
Dim l As Double, t As Double, w As Double, h As Double
Dim Caseàcocher As Object
LastRw = ActiveSheet.Cells(Rows.Count, 1).End(xlUp).Row
EffaceCaseàcocher
For i = 2 To LastRw
With Cells(i, 7) 'colonne G
l = .Left + 2
t = .Top + 1
w = .Width - 2
h = .Height - 2
End With
With ActiveSheet
Set Caseàcocher = .CheckBoxes.Add(l, t, w, h)
With Caseàcocher
.Characters.Text = ""
.OnAction = "Caseàcocher_Cliquer"
.Placement = xlMove
End With
End With
Next
End Sub
Sub EffaceCaseàcocher()
For Each sh In ActiveSheet.Shapes
If Left(sh.Name, 9) = "Check Box" Then sh.Delete
Next
End Sub
Sub AfficherLignes()
Cells.EntireRow.Hidden = False
For Each sh In ActiveSheet.Shapes
If Left(sh.Name, 9) = "Check Box" Then
If sh.ControlFormat.Value = xlOn Then sh.ControlFormat.Value = xlOff
End If
Next
End Sub
Bonjour Sabv,
Je te remercie de ta réponse rapide. Mes excuses de répondre maintenant, j'ai profité du long weekend
C'est un bon début, parfait le système de validation et de commentaires que tu as fait, c'est ce que je voulais
Après je me demande l'utilité de ma colonne "Validé", je pense que cela complique la macro...
Je pense que cela me serai plus pratique :
- Une fois que je remplis une case commentaire, la ligne change de couleur (couleur claire), et rajoute la date & heure de modifications en guise de clôture.
- Et juste un bouton "Afficher/Masquer" les lignes remplis par des commentaires.
Ma demande serai t'elle faisable?
Joe
oui, voilà
Merci à toi
Je vais essayer de rentrer toute mes informations maintenant
Bonne journée