Formule NB.SI sur dates

Bonjour,

Comment peut-on faire un NB.SI sur des dates comme suit :

Dimanche

Lundi

Mardi

Mercredi

Jeudi

Vendredi

Samedi

Dimanche

Je veux savoir le nombre de lundi, mardi, etc mais le format des jours n'est pas en texte. Du coup la formule ne reconnaît pas les jours. Les jours de la semaine sont obtenus à partir d'une cellule indiquant 01.01.2017, qui donne automatiquement les jours.

Quelqu'un a une idée ?

Merci beaucoup

Bonjour et bienvenue,

S'il s'agit bien de dates, reconnues comme telles par Excel, quelque chose comme ce qui suit devrait fonctionner:

=SOMMEPROD((JOURSEM($A$4:$A$49;2)=LIGNES($1:1))*1)

... Formule à recopier sur les 6 lignes suivantes. Le premier résultat correspondra aux lundis, le septième aux dimanches.

En cas de problème, la liste des dates dans un fichier déposé dans ton prochain message aiderait à clarifier

AnaAllroad a écrit :

Je veux savoir le nombre de lundi, mardi, etc mais le format des jours n'est pas en texte. Du coup la formule ne reconnaît pas les jours. Les jours de la semaine sont obtenus à partir d'une cellule indiquant 01.01.2017, qui donne automatiquement les jours.

Un petit extrait "tout terrain" de ton fichier nous permettrait d'y voir plus clair !

Merci pour la réponse. Ne maîtrisant pas du tout les matrices, je vous joins une partie de mon document. En jaune ce sont les chiffres que j'aimerais ressortir, à savoir le nombre de lundi-mardi, etc dans le mois.

Merci d'avance

Ana

Voici

U.Milité avait raison d'utiliser JOURSEM

Ton Lundi au format jjjj n'est qu'une façade, la cellule contient la date en 42736 (1/1/2017) et suivants ...

Bonjour le forum,

C37 :

=SOMMEPROD(--(JOURSEM($A$3:$A$33;2)=LIGNE()-36))

A tirer vers le bas.

@ U. Milité & mbbp : ne pas oublier aussi les cases à côté ! (somme)

AnaAllroad a écrit :

Je veux savoir le nombre de lundi, mardi, etc mais le format des jours n'est pas en texte. .

Bonsoir

Steelson a écrit :

@ U. Milité & mbbp : ne pas oublier aussi les cases à côté ! (somme)

Pour varier les plaisirs et répondre à cette même question, on pouvait aussi écrire, en C37:

=SOMME(SI(TEXTE($A$3:$A$33;"jjjj")=A37;1))

mais il faut valider avec Ctrl+Shift+Enter avant de recopier vers le bas.

Si on veut additionner les valeurs de la colonne C, pour les différents jours de la semaine, utiliser, en B37:

=SOMME(SI(TEXTE($A$3:$A$33;"jjjj")=A37;$C$3:$C$33))

Valider comme la précédente.

Intéressante ta formule !

Je penche quand même plutôt vers une solution TCD comme ici :

Un immense merci pour ces réponses, toutes plus compliquées les unes que les autres, mais ça fonctionne et c'est l'essentiel

Merci !

Belle journée enneigée depuis la Suisse