Envoi de mails BAL générique Outlook via VBA
A
Bonjour à tous,
Suite à de nombreuses recherches (grâce auxquelles j'ai le début de mon code aujourd'hui), je fais appelle à vous car je ne trouve pas la réponse à mon problème
Je souhaiterai pouvoir envoyer un mail via Outlook avec PJ mais pas de ma boite perso, d'une boite générique de l'entreprise à laquelle j'ai accès dans Outlook également.
Envoyer mail --> c'est bon (voir code et fichier joint)
Avec PJ --> c'est bon (voir code et fichier joint)
Envoyer de la boite mail générique --> PAS bon
Mon code est le suivant:
Sub UseOutlook()
Dim MonOutlook As Object
Dim MonMessage As Object
' On crée une instance d'Outlook :
Set MonOutlook = CreateObject("Outlook.Application")
' Et on crée un élément Outlook, qui sera un message E-Mail :
Set MonMessage = MonOutlook.CreateItem(0)
'MonMessage.SendUsingAccount = MonOutlook.Session.Accounts("adresse mail générique@entreprise.fr")
MonMessage.To = "adresse-destinataire@destinataire.fr"
'MonMessage.Cc = "bidule@machin.com"
'MonMessage.Bcc = "chose@machin.com"
MonMessage.Subject = "Quel beau soleil"
MonMessage.body = "N'est ce pas un beau temps pour aller à la piscine ?"
'Joindre un fichier
MonMessage.Attachments.Add "C:\Users\fichier joint.xls"
MonMessage.send
Set MonOutlook = Nothing ' On ferme
MsgBox "Le mail à bien été envoyé !"
End Sub
Private Sub Commande152_Click()
UseOutlook
End Sub
Je joins également un fichier Excel si ça peut aider dans la compréhension.
Si je n'ai pas été assez clair, n'hésitez pas à me demanader des précisions.
Merci
Anthony
A
Il suffit de rajouter la ligne de code suivante:
MonMessage.SentOnBehalfOfName = "AdresseEntreprise@entreprise.fr"
Code complet:
Sub UseOutlook()
Dim MonOutlook As Object
Dim MonMessage As Object
' On crée une instance d'Outlook :
Set MonOutlook = CreateObject("Outlook.Application")
' Et on crée un élément Outlook, qui sera un message E-Mail :
Set MonMessage = MonOutlook.CreateItem(0)
MonMessage.SentOnBehalfOfName = "AdresseEntreprise@entreprise.fr"
MonMessage.To = "adresse-destinataire@destinataire.fr"
'MonMessage.Cc = "bidule@machin.com"
'MonMessage.Bcc = "chose@machin.com"
MonMessage.Subject = "Quel beau soleil"
MonMessage.body = "N'est ce pas un beau temps pour aller à la piscine ?"
'Joindre un fichier
MonMessage.Attachments.Add "C:\Users\fichier joint.xls"
MonMessage.send
Set MonOutlook = Nothing ' On ferme
MsgBox "Le mail à bien été envoyé !"
End Sub
Private Sub Commande152_Click()
UseOutlook
End Sub