Avoir un historique d'intervention

Question

J'ai besoin de réaliser un fichier regroupant chaque intervention réalisé sur des "cloches" et "raccord". Il faut juste le nom de la cloche ou du raccord, la date d'intervention. Il faut par la suite que toutes ces informations soient gardées sur un onglet pour avoir un historique. C'est pourquoi j'ai commencé à réalisé le fichier en pièce jointe. Sur la Feuille 1 sont schématisés les cloches et raccords, sur la feuille 2 on retrouve leurs noms et je comptais mettre l'ensemble de l'historique sur la feuille 3. La feuille 1 doit être extrêmement simple d'utilisation et la feuille 3 doit être relativement simple à comprendre. Je pensais faire un bouton sur chaque cloche ou raccord, qui copierai dans la feuile 3 la date du jour (qui se serait mis automatiquement) et le nom de la cloche en question. Mais que les informations se mettent en dessous de celles déjà présentent dans la feuille 3. Mais je ne sais pas faire ça. Quelqu'un saurait m'aider? Peut-être que je veux faire compliqué alors que l'on peut faire très simple aussi. Merci à vous Aurélie...

andrea73 · Accepted Answer

(re) Et voilà ...

Avie · Answer

Ne serait-il pas aussi simple de faire un tableau où la date est simplement rentrée colonne A, l'utilisateur indique sur quoi il est intervenu colonne B ?

Simple supposition si tu as juste 2 colonnes ça ne devrait pas être trop dur pour l'utilisateur... (si tes cloches et raccords sont identifiés sur le terrain !)

andrea73 · Answer

Bonjour Aurelie D (Avie)

Voici une proposition....

Il faut juste cliquer sur une image "cloche" ou "raccord" et l'historique est créé automatiquement dans l'onglet HIST

PS/ Attention pour l'instant seules les quelques premières images fonctionnent, il s'agit d'un exemple pour voir si cela repond à ton attente ! nous verrons comment faire en sorte que toutes soient cliquables par la suite si tu valides !

89cloches-v2.xlsm (53.23 Ko)

andrea73 · Answer

(re) As-tu compris comment j'ai fait ...

melch · Answer

Clique droit sur une forme, exemple la cloche S1, afin de la sélectionner sans activer la macro.

A gauche de ta barre de formule tu as son nom qui s'affiche. Ici, le nom de la forme qui représente la cloche S1 c'est Ellipse 311.

Tu remplaces "Ellipse 311" par "Cloche S1" et tu fais Entrer.

andrea73 · Answer

Bonjour Aurelie D, (melch)

C'est à peu près ça melch... puis après j'affecte une macro-cmde (toujours la même) nommée évidement QuandClic

Cette procédure QuandClic (gère donc le clic sur l'une de tes formes "cloches" ou "raccord")

J'ai donc nommé les premières formes en fonction des éléments qu'elles représentent (Cloche P1, Cloche P2, Raccord P1 P2, Raccord P2 P3...) pour pouvoir les repérer "plus facilement" que Ellipse 1231 ou Forme Machin 98)

Ensuite que fait la procédure ?

Public wsClic As Object ' Permet de déterminer un objet qui représentera l'onglet des "cloches" et "raccords"
Public wsHist As Object ' -      -  -          -  -     -   -            -        HISTORIQUE

Sub Init()
    Set wsClic = Worksheets("CLIC") '   on affecte le nom des onglets aux objets
    Set wsHist = Worksheets("HIST") '   ws devant chaque objet sert à se souvenir qu'il s'agit d'un WorkSheet donc d'un Onglet
End Sub
Sub Done()
    Set wsClic = Nothing    '   après le traitement il faut "détruire" les objets
    Set wsHist = Nothing
End Sub
Function TrouverLigneHist() As Double           ' Fonction pour TROUVER la derniere LIGNE connue de l'HISTorique
Dim derLig As Double                            ' cette variable représentera donc la DERniere LIGne connue
    With wsHist                                 ' Avec l'onglet HISTorique faire...
        derLig = .Cells(5, 1).End(xlDown).Row   ' la DERniere LIGne = la derniere cellule vide à partir de ligne 5,colonne 1
        If derLig = Rows.Count Then             ' Si on arrive sur la derniere ligne Excel
            ' ROWS.COUNT est le numéro de la derniere ligne d'excel
            ' (65535 ou plus selon les versions)
            ' Donc si on arrive sur cette ligne c'est que l'historique est vide
            derLig = 6                          ' il faut alors revenir au debut de l'HISTorique
        Else                                    ' Sinon
            derLig = derLig + 1                 ' il faut passer à la suivante
        End If                                  ' Fin du Si (le test de la derniere ligne)
    End With                                    ' Fin du Avec
    ' Et volia la DERniere LIGne est trouvee
    TrouverLigneHist = derLig                   ' la fonction doit donc renvoyer cette valeur
End Function
Sub QuandClic()                                 ' QUAND on CLIC sur une image "cloche" ou "raccord"
Dim derLig As Double                            ' pour pouvoir recuperer la DERniere LIGne grace a la fonction
    Init                                        ' il faut initialiser le nom des onglets dont on se sert
    derLig = TrouverLigneHist                   ' il faut rechercher la DERniere LIGne
    With wsHist                                 ' Avec l'onglet HISTorique faire...
        .Cells(derLig, 1) = Date                ' la cellule de la DERniere LIGne, colonne 1 egal DATE du jour
        .Cells(derLig, 2) = Application.Caller  ' -  -       -  -  -        -      -       2 -    le nom de l'objet appelant
    End With                                    ' Fin du Avec
    Done                                        ' Detruire les affectations des noms d'onglets pour liberer la memoire !
End Sub

Pour te simplifier la tâche je vais terminer le nommage... puisque tu valides !

andrea73 · Answer

(re)

Je viens de terminer le "nommage" ... je fais quelques tests pour vérifier que tout fonctionne et... le fichier arrive ensuite !

Aurélie D a écrit :
Merci pour cette explication détaillée et très claire.

merci comme dises certains sur le forum "un merci ne coute pas très cher, mais il fait toujours plaisir !"

Aurélie D a écrit :
Peut être vais-je réussir à comprendre les macros les plus simple petit à petit (je garde espoir).

je te le souhaite... il y a tant de choses à faire avec la programmation- et ce n'est pas tout à fait

Aurélie D a écrit :
du chinois ni même de l'extraterrestre).

c'est du VBA (Visual BASIC for Application - le mot BASIC est en majuscule puisqu'il s'agit d'un sigle et non d'un acronyme qui veut dire :Beginner's Allpurpose Symbolic Instruction Code ou dans la langue de Molière Ensemble d'instructions symboliques à l'usage des DEBUTANTS) donc il est fait pour que tu

Aurélie D a écrit :
garde espoir

melch · Answer

@andrea

en tout cas merci beaucoup, tu m'as appris un truc nouveau : application.caller

Je planchais sur le problème de Aurélie et je ne connaissais pas du tout cette instruction

(Je suis tout a fait d'accord, un merci ça vaut de l'or)

andrea73 · Answer

Attention par contre à l'effacement de l'historique ! il efface tout (après avoir demandé confirmation) ! Je n'ai mis en place aucune sauvegarde, ou sélection de date(s) à effacer ...