Repartition

Bonjour,

Mon problème aujourd’hui est le suivant :

J’ai une base de données en feuille BD.

En feuille « Repart » je fais un tirage au sort par la formule RechercheV et Petite Valeur. Jusque-là ça va.

Ce que je voudrais c’est que le tirage prenne en compte la valeur de la colonne A. je m’explique j’introduis un autre paramètre en B3 qui correspond à un choix dans la colonne A de la BD et que le tirage ne se fasse que dans les cellules qui répondent à cette nouvelle condition.

Exemple : si j’introduis en B3= 1400, le tirage se fera entre les cellules C25- C45.

Si B3= 1200 tirage entre C4 – C24

Je vous remercie beaucoup pour votre aide indispensable.

Bonjour,

en C7 :

=SIERREUR(INDEX(BD!$C$4:$C$76;EQUIV(PETITE.VALEUR(SI(BD!$A$4:$A$76=$B$3;BD!$B$4:$B$76);COLONNES($C:C));SI(BD!$A$4:$A$76=$B$3;BD!$B$4:$B$76);0));"")

@ valider par Ctrl+Shift+Enter

@ tirer vers la droite

@ + +

Re,

avec une formule classique :

=RECHERCHEV(PETITE.VALEUR(DECALER(BD!$B$3;EQUIV($B$3;BD!$A$4:$A$76;0);;NB.SI(BD!$A$4:$A$76;$B$3));COLONNES($C:C));DECALER(BD!$B$3;EQUIV($B$3;BD!$A$4:$A$76;0);;NB.SI(BD!$A$4:$A$76;$B$3);2);2;0)

@ tirer vers la droite

@ + +

EXCELLENT,

je vous remercie infiniment c'est excellent

Bonsoir,

Est il possible de mettre dans une cellule par exemple D3 le nombre de case à tirer dans la repartition.

Si par exemple je met D3 =5 j'aurais une reponse dans les 5 cases c a d de C7 à G7.

Merci pour votre aide.

Re,

en C7 :

=SI(COLONNES($C:C)>$D$3;"";RECHERCHEV(PETITE.VALEUR(DECALER(BD!$B$3;EQUIV($B$3;BD!$A$4:$A$76;0);;NB.SI(BD!$A$4:$A$76;$B$3));COLONNES($C:C));DECALER(BD!$B$3;EQUIV($B$3;BD!$A$4:$A$76;0);;NB.SI(BD!$A$4:$A$76;$B$3);2);2;0))

@ tirer vers la droite

@ + +

Merci Rachid

Tu es un Grand Maître.

Cordialement