Formule vacances de pâques

Bonjour,

En Belgique (je ne sais pas si c'est pareil ailleurs), certaines écoles ont droit à 2 semaines de congés pour Pâques. Sachant que la date de Pâques est mobile, j'ai réussi à déterminer une formule qui me trouve la date du Lundi de pâques ('Annee' fait référence à une cellule contenant l'année de laquelle on souhaite trouver le lundi de pâques) :

=SI(MOD(19*MOD(Annee;19)+24;30)+MOD(2*MOD(Annee;4)+4*MOD(Annee;7)+6*MOD(19*MOD(Annee;19)+24;30)+5;7)-9<=0;DATE(Annee;3;22+MOD(19*MOD(Annee;19)+24;30)+MOD(2*MOD(Annee;4)+4*MOD(Annee;7)+6*MOD(19*MOD(Annee;19)+24;30)+5;7));DATE(Annee;4;MOD(19*MOD(Annee;19)+24;30)+MOD(2*MOD(Annee;4)+4*MOD(Annee;7)+6*MOD(19*MOD(Annee;19)+24;30)+5;7)-9))+1

Je souhaite obtenir une formule qui me trouve le 1er jour des vacances de pâques... elles aussi sont mobiles, mais je galère un peu avec les critères (surtout le dernier^^):

1°- Lorsque le jour de Pâques tombe entre le 1er et le 15 avril, les vacances de printemps débutent le premier lundi d’avril.

2° - Lorsque le jour de Pâques tombe pendant le mois de mars, les élèves pourront partir en congé dès le lundi après le jour de Pâques.

3° - Lorsque le jour de Pâques tombe après le 15 avril, les vacances de printemps commencent le deuxième lundi avant le jour de Pâques (* - voir le tableau en fin de dossier). Dans ce cas, le lundi de Pâques sera également férié et les élèves auront un jour de congé supplémentaire. Les vacances de printemps durent toujours deux semaines.

Code qui ne fonctionne pas tout le temps 'AK5' contient la formule du lundi de Pâques) ;

=SI(MOIS(AK5-1)=3;AK5-1;SI(AK5-1<DATE(Annee;4;16);STXT(RECHERCHEV("L*";TEXTE({1;2;3;4;5;6;7}&"/"&4&"/"&Annee;"jjj j/m/aaa");1;0);5;10)*1;(AK5-2)-MOD((AK5-1)-2;14)*2))

Quelqu'un peut m'aider ? :p

Bonjour,

Pour le premier jour des vacances :

=SI(MOIS(AK5-1)=3;AK5;SI(AK5-1>DATE(Annee;4;15);AK5-14;DATE(Annee;4;7)-JOURSEM(DATE(Annee;4;7);3)))

A+

MDR, toute petite formule... super efficace. Merci l'ami <3