Image userform valeur textbox

Bonsoir

Dans un userform j'ai 5 textbox avec une valeur, j'aimerai avoir une image sous le textbox qui a la plus grande valeur

Merci

Bonsoir,

tu rajoute des contrôles images sous chacun de tes textbox .. , puis tu joue sur leur visibilité ....

ainsi avec 5 textbox nommés textbox1 à Textbox5 et cinq contrôle image correspondant image1 à image5 , inspire toi de ce code :

Sub MajVisibiliteImage()
Dim i As Integer
Dim iMax As Integer
Dim iValMax As Double
'Initialise avec textBox1
iMax = 1
iValMax = TxtDble(TextBox1.Value)
'Boucle sur les textbox restant en conservant le Maxi..
For i = 2 To 5
 If TxtDble(Controls("textbox" & i).Value) > iValMax Then
    iValMax = TxtDble(Controls("textbox" & i).Value)
    iMax = i
 End If
Next
' Affiche les contrôles images
For i = 1 To 5
    Controls("Image" & i).Visible = (iMax = i)
Next
End Sub

'
' Transforme textbox en double
'
Function TxtDble(st As String) As Double
    TxtDble = Val(Replace(st, ",", "."))
End Function

'
' Appel mise à jour affichage sur changement de valeur ou ouverture vue
'

Private Sub TextBox1_Change()
MajVisibiliteImage
End Sub

Private Sub TextBox2_Change()
MajVisibiliteImage
End Sub

Private Sub TextBox3_Change()
MajVisibiliteImage
End Sub

Private Sub TextBox4_Change()
MajVisibiliteImage
End Sub
Private Sub TextBox5_Change()
MajVisibiliteImage
End Sub

Private Sub UserForm_Activate()
MajVisibiliteImage
End Sub

Private Sub UserForm_Click()

End Sub

Merci pierre.jy

C'est bon, avec ce code j'ai réussi à finir mon fichier

Bon weekend