Ajout d'une ligne dans l'ordre croissant

Bonjour, j'ai réussi a créer un code permettant d'ajouter une ligne dans un tableau a partir d'un formulaire situé sur une autre page, cependant je ne connais que le code pour l'ajouter sur la première ligne vide. je souhaiterais qu'elle s'ajoute dans l'ordre, la première colonne étant un nombre.

Voici mon code, quelqu'un sait-il ce que je peux changer ?

Sub Enregistrement()

'

' Enregistrement Macro

'

'

Dim lignevide As Integer

Dim CodeUtilisateur

Dim NomUtilisateur

CodeUtilisateur = Range("B1").Value

NomUtilisateur = Range("B3").Value

Sheets("Utilisateur").Select

lignevide = Columns("A").Find("", Range("A1"), xlValues).Row

Cells(lignevide, "A") = CodeUtilisateur

Cells(lignevide, "B") = NomUtilisateur

Sheets("Gestion Utilisateur").Select

Range("B1", "B3").ClearContents

Dim reponse As String

reponse = MsgBox("Utilisateur ajouté !", vbOKOnly, "Confirmation")

End Sub

Bonjour,

Essaie ceci :

Public Sub Enregistrement()
Dim lignevide As Long
Dim CodeUtilisateur As Long
Dim NomUtilisateur As String

    CodeUtilisateur = Range("B1").Value
    NomUtilisateur = Range("B3").Value

    With Worksheets("Utilisateur")
        lignevide = .Cells(Rows.Count, 1).End(xlUp).Row + 1
        .Cells(lignevide, "A").Value = CodeUtilisateur
        .Cells(lignevide, "B").Value = NomUtilisateur
        .Cells(1, "A").Sort _
                key1:=.Cells(2, "A"), _
                order1:=xlAscending, _
                Header:=xlGuess
    End With

    Worksheets("Gestion Utilisateur").Range("B1", "B3").ClearContents

    MsgBox "Utilisateur ajouté !", vbOKOnly + vbInformation, "Confirmation"

End Sub

Ça fonctionne, merci beaucoup

Rechercher des sujets similaires à "ajout ligne ordre croissant"