Modifier titre ordonnées dans graphique par VBA

Bonjour

J'ai pris en charge un pb soulevé sur le forum mais je coince sur la modification du titre de l'axe des ordonnées.

j'ai enregistré la procédure de création, qui exécute bien toutes les étapes manuelles.

Lorsque l'on relance la macro, le titre de l'axe vertical n'est pas généré.... donc pas trouvé, donc par modifiable par formule... donc bug sur la ligne

ActiveChart.ChartArea.Select

ActiveChart.SetElement (msoElementPrimaryValueAxisTitleAdjacentToAxis)

ActiveChart.Axes(xlValue).AxisTitle.Select ' ça coince le titre de l'axe n'est pas ajouté par la ligne précédente

Selection.Characters.Text = Range("a3").Value

Merci d'avance pour votre aide

Cordialement

FINDRH

Bonjour,

Un début de réponse pour la construction de ton graphique.

Bonne continuation.

Cdlt.

Option Explicit

Public Sub DEMO()
Dim ws As Worksheet
Dim rngChart As Range
Dim objchart As ChartObject

    Set ws = ActiveSheet

    With ws
        .ChartObjects(1).Delete
        Set rngChart = .Cells(5, 1).CurrentRegion
        Set objchart = .ChartObjects.Add(Left:=400, Top:=50, Width:=350, Height:=250)
        With objchart.Chart
            .ChartType = xlXYScatter
            .SetSourceData Source:=rngChart
            .HasTitle = True
            .ChartTitle.Characters.Text = ws.Cells(3, 1)
            .HasLegend = True
            .Legend.Position = xlLegendPositionBottom
        End With
    End With

    Set objchart = Nothing
    Set rngChart = Nothing
    Set ws = Nothing

End Sub

Bonjour Jean Eric

Merci pour ce code qui fonctionne parfaitement

Comment fais je apparaître le titre de l'axe vertical et lui affecte la valeur de la cellule (3,1) ?

merci pour ton éclairage !

Cordialement

FINDRH

Re,

Essaie ainsi :

Public Sub DEMO()
Dim ws As Worksheet
Dim rngChart As Range
Dim objchart As ChartObject

    Set ws = ActiveSheet

    With ws
        On Error Resume Next
        .ChartObjects(1).Delete
        On Error GoTo 0
        Set rngChart = .Cells(5, 1).CurrentRegion
        Set objchart = .ChartObjects.Add(Left:=400, Top:=50, Width:=350, Height:=250)
        With objchart.Chart
            .ChartType = xlXYScatter
            .SetSourceData Source:=rngChart
            .HasTitle = True
            .ChartTitle.Characters.Text = ws.Cells(1, 1)
            .HasLegend = True
            .Legend.Position = xlLegendPositionBottom
            With .Axes(xlValue)
                .HasTitle = True
                With .AxisTitle
                    .Caption = ws.Cells(3, 1)
                    '.Font.Name = "Calibri"
                    '.Font.Size = 10
                End With
            End With
        End With
    End With

    Set objchart = Nothing
    Set rngChart = Nothing
    Set ws = Nothing

End Sub

Re Bonjour et Re merci

ça marche parfaitement et je vais pouvoir répondre au problème

Ta syntaxe mérite d'être mise au niveau de la formation sur les graphiques..... je ne dois pas être le seul demandeur et j'en ai déjà bavé sur d'autres créations de graphiques....

Encore mille merci

Cordialement

FINDRH

Re,

Je dois avouer que ce n'est pas simple et l'enregistreur de macros ne nous aide pas.

Il faut repérer les mots clés et faire F1.

A te relire, si tu as besoin d'informations complémentaires.

Pense à clore le sujet si tu es satisfait.

Cdlt.