Gestion des doublons

Bonjour

J'ai une liste de doublons qui se présente ainsi

ID Société Date de facturation

8160157 SOCIETE DE DETECTEURS 09/03/2015

8160157 SOCIETE DE DETECTEURS 09/03/2014

8160311 PARTNER 04/11/2014

8160311 PARTNER 10/06/2013

8160471 AXE METAL 19/03/2015

8160471 AXE METAL 19/03/2014

8161475 ESC OF BUSINESS 16/12/2014

8161475 ESC OF BUSINESS 21/01/2015

8161475 ESC OF BUSINESS 16/12/2011

8161475 ESC OF BUSINESS 21/01/2012

Je souhaite supprimer les doublons ( ID, SOCIETE) mais que Excel me garde la date de facturation la plus récente

Quelle formule dois je utiliser?

Merci par avance pour votre aide

Sophie

Bonjour,

Dans un premier temps, tu sélectionnes tes 3 colonnes et tu fais un tri personnalisé sur la date de facturation, du plus récent au plus ancien,

Ensuite, dans Données > Supprimer les doublons, tu sélectionnes les colonnes contenant les doublons (ID et Société) et tu effectues la suppression de doublons .

A+

Bonjour

Si j'ai bien compris tes données sont dans une méme cellule...

Ci joint une proposition de macro éliminant les doublons tel que tu le souhaites.

Copier tes données sur la feuille TRAV à partir de la cellule A4 puis cliquer sur le bouton doublon

Cordialement

FINDRH

22sudoubl-date.xlsm (21.41 Ko)

Mille mercis à vous 2

Ça fonctionne !!!!

Très bonne journée

Sophie

Impeccable

merci de clore le sujet !

FINDRH

Bonsoir le forum,

Tes données en Feuil1 à partir de A1.

Sans tri préalable de tes données.

Restitution à côté du tableau original.

Option Explicit

Sub Dernier_En_Date()
Dim a, i As Long, j As Long, txt As String, n As Long
    Application.ScreenUpdating = False
    With Sheets("Feuil1").Range("a1").CurrentRegion
        a = .Value
        With CreateObject("Scripting.Dictionary")
            .CompareMode = 1
            For i = 1 To UBound(a, 1)
                txt = Join$(Array(a(i, 1), a(i, 2)))
                If Not .exists(txt) Then
                    n = n + 1
                    .Item(txt) = n
                    For j = 1 To UBound(a, 2)
                        a(n, j) = a(i, j)
                    Next
                Else
                    If a(.Item(txt), 3) <= a(i, 3) Then
                        For j = 1 To UBound(a, 2)
                            a(.Item(txt), j) = a(i, j)
                        Next
                    End If
                End If
            Next
        End With
        With .Offset(, .Columns.Count + 1)
            .CurrentRegion.Clear
            .Cells(1).Resize(n, UBound(a, 2)).Value = a
            With .CurrentRegion
                .Font.Name = "calibri"
                .Font.Size = 10
                .HorizontalAlignment = xlCenter
                .VerticalAlignment = xlCenter
                .Borders(xlInsideVertical).Weight = xlThin
                .BorderAround Weight:=xlThin
                With .Rows(1)
                    .Font.Size = 11
                    .Interior.ColorIndex = 38
                    .BorderAround Weight:=xlThin
                End With
                .Columns.AutoFit
                .Sort key1:=.Cells(3), order1:=1, Header:=1
            End With
        End With
    End With
    Application.ScreenUpdating = True
End Sub

klin89

Rechercher des sujets similaires à "gestion doublons"