Fusionner des doublons

Hello a vous ami(sère, je sais jeux de mots foireux, mais mon cerveau chauffe et nous sommes en fin de semaine !!!)

Mon soucis j'ai un tableau qui contient peux importe, dirons nous des articles, et des quantité par jours, mais pas tous les jours (ah ah ) ce que je cherche c'est a ne plus avoir de doublons (comme c'est original ) et que quand le doublon a deux case le même jours rempli il s'aditionne et que sinon ils ce complète. comme cela je n'aurais plus de doublon mais aussi pas de perte de donnés ni de quantité. ci-joint (j'en aurais peut être besoin, d'ailleurs) un tableau pour montrer "le tu vois ce que je veux dire "!!!

Merci par avance qui que vous soyez et quoique vous fassiez (même jeter un coup d'oeil)...

bonne soirée ou journée

au fait suis je sot, je travail sur excel 2007 ( oui oui cela existe encore)

Bonjour TaigaLupus,

Je ne comprends pas vraiment comment ton fichier est alimenté et comment tu souhaites procéder :

• En remplissant le fichier ligne par ligne (et dans ce cas lancer une macro qui formate le tableau ?)
• Via un formulaire ?

En espérant pouvoir t'aider !

Bonsoir,

Une proposition à étudier.

Tout d'abord merci et waouuu quel vitesse ...

Merci Jean-Eric, mais ce que je voudrais c'est créer un code pour hop un clic sur un bouton et feu...

car mon pote est encore moins un foudre de guerre sur excel que moi ..

mais sincerement merci

cher JS Lombard,

merci pour tes questions je te joint le fichier complet.

en faite on copie les colonnes d'une feuille vers le tableau et après on joue au puzzle magique (ouais je le reconnais pas super pratique)

en esperant que tu comprendras mieux

merci

par un tableau croisé dynamique ...

Merci , pour la solution du TCD, mais (je sais j'exagere) j'aimerais faire un systeme avec un bouton et du VBA pour 2 raisons, en même temps je decortique le code et j'apprends et ensuite je ne suis pas le seul a utiliser le fichier et j'aimerais limiter le risque d'erreur et la multiplication des feuilles.

Merci merci merci

Re,

Une nouvelle proposition avec TCD crée en VBA.

A te relire.

Cdlt.

Option Explicit
Option Private Module

Public Sub Creer_TCD()
Dim wb As Workbook
Dim wsData As Worksheet, wsPT As Worksheet
Dim lCol As Long, i As Long
Dim ptCache As PivotCache
Dim pt As PivotTable
Dim ItemName As String
Dim xlCalc As XlCalculation

    With Application
        xlCalc = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
    End With

    Set wb = ThisWorkbook
    Set wsData = Feuil1: Set wsPT = Feuil2

    On Error Resume Next
    wsPT.PivotTables(1).TableRange2.Delete
    On Error GoTo 0

    lCol = wsData.ListObjects(1).ListColumns.Count

    Set ptCache = wb.PivotCaches.Create(xlDatabase, wsData.ListObjects(1).Range, 3)
    Set pt = ptCache.CreatePivotTable(wsPT.Cells(1), "PT_1", , 3)

    pt.ManualUpdate = True
    pt.AddFields RowFields:="Nom"

    For i = 2 To lCol
        ItemName = wsData.Cells(i)
        With pt.PivotFields(ItemName)
            .Orientation = xlDataField
            .Name = ItemName & Chr(160)
            .Function = xlSum
            .NumberFormat = "#,##0"
        End With
    Next i

    With pt
        .RowAxisLayout xlTabularRow
        .ColumnGrand = False
        .RowGrand = False
        .TableStyle2 = "PivotStyleMedium2"
        .DisplayFieldCaptions = False
        .ManualUpdate = False
    End With

    With wsPT
        .Activate
        .Cells(1).Select
    End With

    Application.Calculation = xlCalc

    Set pt = Nothing
    Set ptCache = Nothing
    Set wsData = Nothing: Set wsPT = Nothing
    Set wb = Nothing

End Sub

je vais me faire une joie de le tester demain, et d'essayer de comprendre (msgbox et ton ami). et je ne manquerais pas de revenir vers toi.. merci beaucoup, (mais la vache tu trace)