Changement couleur+ajout texte lors d'un double clic

Bonsoir à tous!!

Je reviens vers vous pour un complément d'informations sur une macro existante. En effet, grâce à une super macro de BrunoM45, j'ai en main une macro qui me permets via un double clic de colorer une cellule et de copier la cellule voisine qui va être stocké dans le clipboard! J'aimerais rajouter à cette fonction de colorisation, la possibilité d'ajouter un texte: exemple "mail sélectionné".

Je vous joints le fichier en question pour une meilleure compréhension de la problématique.

Un grand MERCI d'avance pour tous vos retours^^

Bonsoir,

Il suffit d'ajouter deux lignes dans ta macro :

Option Explicit
' Il faut cocher la référence : Microsoft Forms 2.0 Object Library
Dim DataObj As New MSForms.DataObject
Dim Liste As String

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
  If Not Intersect(Target, Range("B:B")) Is Nothing Then
    ' Annuler le mode édition de la celule
   Cancel = True
    ' Si la couleur de la cellule est déjà verte
   If Target.Interior.Color = 5287936 Then
      ' Enlever al couleur
     Target.Interior.Color = xlNone
     Target.Value = ""
      ' Supprimer le nom de la liste
     Liste = Replace(Liste, Target.Offset(0, -1) & ";", "")
    Else
      ' SInon mettre la cellule en vert
     Target.Interior.Color = 5287936
     Target.Value = "Mail sélectionné"
      ' Ajouter le nom à la liste
     Liste = Liste & Target.Offset(0, -1) & ";"
    End If
    ' Placer cette liste dans le clipboard
   With DataObj
      .SetText Liste
      .PutInClipboard
    End With
  End If
End Sub

Bonne soirée

Bonjour Sharney,

Merci pour ce petit bout de code!! C'est parfait... juste ce dont j'avais besoin!!

Bonne journée.

Pas de soucis.

Bonne journée à toi aussi.

Rechercher des sujets similaires à "changement couleur ajout texte lors double clic"