Somme des cellules avec fond de couleur

Bonjour, je voudrais faire une formule qui additionne le nbrs de cellule avec un fond de couleur précis, mettons rouge.

Donc ma formule vérifier les cellule F8, F14, F20, F28, F34, F40, F46, F52, F58, F64,F70 et F76. +1 chaque fois qu'une de ces cellules à comme fond de couleur rouge.

Bonjour,

Merci de joindre un fichier.

Cdlt.

Re,

A étudier et assimiler

Function Somme_couleur(CellColor As Range, SumRange As Range)
Dim mycell As Range
Dim iCol As Integer
Dim myTotal
    ' get the target color
    iCol = CellColor.Interior.ColorIndex
    ' look at each cell in the designated range
    For Each mycell In SumRange
        ' if the cell color matches the target Color
        If mycell.Interior.ColorIndex = iCol Then
            ' add the value in the cell to the total
            myTotal = WorksheetFunction.Sum(mycell) + myTotal
        End If
    Next mycell
    Somme_couleur = myTotal
End Function
Function Compte_couleur(CellColor As Range, SumRange As Range)
Dim mycell As Range
Dim iCol As Integer
Dim myTotal
    ' get the target color
    iCol = CellColor.Interior.ColorIndex
    ' look at each cell in the designated range
    For Each mycell In SumRange
        ' if the cell color matches the target Color
        If mycell.Interior.ColorIndex = iCol Then
            ' add the value in the cell to the total
            myTotal = 1 + myTotal
        End If
    Next mycell
    Compte_couleur = myTotal
End Function

function sommecoul(r1 as range, c as integer) as double
For each ce in r1
if ce.interior.colorindex = c then
sommecoul = sommecoul+ce.value
end if
next ce
end function

=sommecoul(F:F;6)

Trouve le color index de ton rouge.. et remplace le dans ta formule

Bonjour le forum,

Dans un module :

Function Couleurs(SearchArea As Object, BgColor As Range) As Integer

Application.Volatile True

Couleurs = 0

MaCoul = BgColor.Interior.ColorIndex

For Each cell In SearchArea

If cell.Interior.ColorIndex = MaCoul Then Couleurs = Couleurs + 1

Next cell

End Function

A1 : avec l'icône "Couleur de remplissage" : choisir la couleur.

Formule : =couleurs(F1:F100;$A$1)

F9 pour actualiser.

mbbp

Sa ne peut pas vérifier sur la ligne F au complet, sa doit être dans des cellules spécifique comme j'ai mentionné car sur d'autre cellule de la ligne F, possible qu'il est des cellules à fond rouge aussi. Ceux-ci seront comptabilisé avec une autre formule.

Mon fichier est vierge présentement...je le commence.

Re,

=couleurs(F8;$A$1)+couleurs(F14;$A$1)+couleurs(F20;$A$1)+couleurs(F28;$A$1)+couleurs(F34;$A$1)+couleurs(F40;$A$1)+couleurs(F46;$A$1)+couleurs(F52;$A$1)+couleurs(F58;$A$1)+couleurs(F64;$A$1)+couleurs(F70;$A$1)+couleurs(F76;$A$1)

mbbp

Bonjour

Une autre façon

Formule à utiliser

=compte(A1;F8;F14;F20;F28;F34;F40;F46;F52;F58;F64;F70;F76)

La 1ère référence est celle qui contient la couleur à tester

Ensuite la fonction

Function Compte(ParamArray Liste())
Dim I As Integer

  Application.Volatile
  For I = 1 To UBound(Liste)
    If Liste(0).Interior.ColorIndex = Liste(I).Interior.ColorIndex Then
      Compte = Compte + 1
    End If
  Next I
End Function

Tu n'es pas limité en nombre de cellule (quoique je n'ai pas testé)

Merci à tous, la soluce de Banzai64 fonctionne bien pour mon besoin.