Copier les données de trois tableaux dans un tableau global

[b]Bonjour,

Je reviens encore une fois vers vous car j'arrive toujours pas à créer des macros toute seule.

Cette fois-ci, j'ai besoin de copier les données de trois feuilles automatiquement dans un tableau global et ce en temps réel pour offrir à la personne s'occupant du suivi un seul tableau regroupant l'ensemble des tableaux.

Est ce que cela est possible?

Dans mon tableau, c'est les feuilles " import-export" , "mm" et " frais généraux" que je souhaite regrouper dans "tableau global".

Si il est possible de préciser la source genre de quelle feuille ca provient ca serait un plus sinon on pourrait s'en passer.

Merci à vous.

Bonne journée[/b]

Bonjour,

J'ai présumé que dans chaque onglet concerné, il y avait au moins une donnée dans chaque cellule de la colonne K.

Copie le code ci-dessous, sélectionne l'onglet "tableau général", fais un clic droit sur le nom de l'onglet, et colle ce code :

Private Sub Worksheet_Activate()
Dim Plg As Range
Dim LesFeuilles
Dim I As Byte
Dim DerLig As Long, DerLigGen As Long
Application.ScreenUpdating = False
LesFeuilles = Array("import-export", "frais généraux", "mm")
Rows("5:" & Rows.Count).Clear
For I = LBound(LesFeuilles) To UBound(LesFeuilles)
    With Sheets(LesFeuilles(I))
        DerLig = .Cells(Rows.Count, "K").End(xlUp).Row
        If DerLig > 4 Then
            DerLigGen = IIf(Me.Cells(Rows.Count, "K").End(xlUp).Row + 1 = 4, 5, Me.Cells(Rows.Count, "K").End(xlUp).Row + 1)
            With Me.Cells(DerLigGen, "A")
                .Value = LesFeuilles(I)
                .Resize(1, 34).Merge
                .HorizontalAlignment = xlCenter
                .Interior.ColorIndex = 3
            End With
            Set Plg = .Range("A5:AH" & DerLig)
            Plg.Copy Me.Cells(DerLigGen + 1, "A")
        End If
    End With
Next I
End Sub

Ainsi, dès que tu sélectionnes cet onglet, les données sont mises à jour...

Et en rouge, les onglets de provenance

Bon dimanche

Bonjour,

Ça fonctionne parfaitement, merci beaucoup. Mais dites moi , est ce que cette macro va se déclencher automatiquement à chaque fois qu'il y'a d'autres lignes qui s'ajoutent dans les feuilles en question??

Merci

Bonne chance

Re-,

La macro va s'exécuter dès que tu viendras sur l'onglet "tableau général"...

Elle va tout effacer, et remettre les données existantes des 3 onglets à ce moment-là.

donc, oui, le tableau sera à jour.

Bonne soirée

Bonjour,

ah d'accord , merci.

Bonne journée