Reporter macro dans plusieurs feuilles d'un même classeur

Bonsoir

J'ai besoin d'un peu d'aide, j'ai créé un classeur avec 12 feuilles mensuelles, j'ai créé une macro afin de reporter certaines données de la feuille janvier sur une autre feuille récap, cela fonctionne mais comment faire pour que cette macro soit applicable à chaque mois , dois je en faire une différente à chaque fois.

Merci d'avance

Jocelyne

Edition: Par Mytå, pour déplacement de la ficelle

Salut le forum

Jocelyne, il faudrait un exemple de ta macro, car avec le nom de la feuille

tu pourrais t'en servir sur toutes tes feuilles..

A te relire.

Mytå

Bonsoir

Lorsque la feuille de janvier est terminée avec sa macro tu la dupliques.

Cela se fait en saisissant l'onglet Janvier et le glisser tout en maintenant la touche ctrl appuyée. La feuille est dupliquée avec tout son contenu (Formule et bouton d'appel des macros et toutes les mises en forme.......)

Bonjour

En XL4, je verrai bien une macro complémentaire XLA applicable sur le Feuille active, mais en VBA, je ne sais pas faire l'équivalent.

Mytå, cela n'est-il pas faisable en VBA ?

Cordialement

Bonjour à tous,

Comme te dit Myta, un exemple serait le bienvenu.

Si ta macro est une SUB placée dans un module, une première idée serait que, dans chaque feuille mensuelle tu mettes un bouton qui exécute cette macro.

Cela te permettra de décider si tu veux mettre tes données en récap ou non.

Amicalement

Dan

merci à tous pour votre aide, j'ai essayé de dupliquer la macro mais cela ne fonctionne pas, je vais essayer d'être plus claire

j'ai un classeur avec 12 feuilles(mensuelles) pour ma gestion bancaire

sur chaque feuille apparait une colonne catégorie, je voudrais pouvoir recopier par macro la catégorie "santé" qui gère mes dépenses et rembrst ss et mutuelle sur une feuille à part afin de pouvoir vérifier, le problème est que chaque feuille est différente et si je duplique la macro toutes mes données ne sont pasprises en compte voila celle de janvier par exemple

Sub janvier()

' Sheets("Janvier").Select

Columns("A:G").Select

Selection.AutoFilter

Selection.AutoFilter Field:=4, Criteria1:="santé"

Range("A59:G78").Select

Selection.Copy

Sheets("essai").Select

Range("A2").Select

ActiveSheet.Paste

Sheets("Janvier").Select

Selection.AutoFilter Field:=4

Application.CutCopyMode = False

Selection.AutoFilter

End Sub

en fait le prob vient de la ligne range car une fois le filtre exécuté ( a59 peut devenir a20 ou autre , idem pour g78 suivant le filtre )

j'espère avoir été assez claire

merci de votre aide

jocelyne

ps: bonne et heureuse année à toutes et tous

Salut le forum

Jocelyne, un première essai à lancer depuis ta feuille mois

Sub MacroCopierFiltre()
    Dim rngSelect As Range

    Range("A1").Select

    ' Filtrage
    Selection.AutoFilter Field:=4, Criteria1:="santé"

    ' rngSelect =   toutes les cellules visibles (non masquées par le filtre)
    '               contigües à la cellule active
    Set rngSelect = ActiveCell.CurrentRegion.SpecialCells(xlCellTypeVisible)

    ' copy de la zone sélectionnée
    rngSelect.Copy Sheets("essai").Range("A1")

    Debug.Print rngSelect.Address

    Selection.AutoFilter

    Set rngSelect = Nothing
End Sub

Mytå

bonjour

effectivement cela fonctionne sur une feuille , bien que le tri prenne en compte trop de colonne, je ne veux pas abuser trop de ta gentillesse, alors je te propose si cela est possible de t'envoyer le dossier excel car je crois que ce sera plus facile pour m'aider

si cela te convient dis moi comment faire

amitiés jocelyne

Salut le forum

Jocelyne, pour me contacter utlise le bouton en dessous de mon message.

Mytå

Salut et bonne année à tous

Sub Test()
ActiveSheet.AutoFilterMode False
With Range("A1:G1").CurrentRegion
    .AutoFilter Field:=4, Criteria1:="santé"
    .Copy Sheets("essai").Range("A2")
End With
End Sub

elle n'est pas très différente de celle de Myrta du grand nord. Maisregarde si ça te convient.

A+

bonsoir

merci à tous pour votre aide, mon problème a été résolu magistralement par Myta mais

je cherche un livre d'initiation car je voudrais essayer de me débrouiller un peu toute seule, avez vous une référence à m'indiquer (pas trop compliqué quand même au départ)

en tous cas encore mille mercis

jocelyne

Salut le forum

La macro utilisée pour le fichier de Jocelyne

Sub MacroCopierFiltre()
Dim rngSelect As Range
Dim Feuille As Variant
Dim Tablo As Variant
Dim DerLigne As Long

Tablo = Array("Jan", "Fev", "Mar", "Avr", "Mai", "Juin", _
                    "Juil", "Aout", "Sep", "Oct", "Nov", "Dec")

Sheets("Santé").Cells.Clear

For Each Feuille In Tablo
    Sheets(Feuille).Select
    Range("A2").Select

    ' Filtrage
    Selection.AutoFilter Field:=4, Criteria1:="santé"

    ' rngSelect =   toutes les cellules visibles (non masquées par le filtre)
    Set rngSelect = Range("A2:G" & Range("D65536").End(3).Row).SpecialCells(xlCellTypeVisible)

    ' Copier la zone filtrée
    DerLigne = Sheets("Santé").Range("D65536").End(3).Row + 2
    rngSelect.Copy Sheets("Santé").Range("A" & DerLigne)
    Sheets("Santé").Range("H" & DerLigne) = Feuille
    Selection.AutoFilter

Next Feuille

    Set rngSelect = Nothing
    Sheets("Santé").Select
End Sub

Jocelyne, pas besoin vraiment de livre, tu peux utiliser l'enregistreur de macro, et avec

la Touche F1 sur un mot tu accès au fichier d'aide. Si tu rencontre des problèmes,

tu peux poster ta macro ici et il y aura toujours quelqu'un pour t'aider.

Mytå

Rechercher des sujets similaires à "reporter macro feuilles meme classeur"